# This overlay provides a set of customized pkgs.

self: super:

{
  qutebrowserWE = super.qutebrowser.override { withWebEngineDefault = true; };
  iosevka-hskl = let
    tags = [
      "ss08" # Use Pragmata Pro Style
      "term" # Disable ligature/ligation
    ];
  in
    super.iosevka.override {
      nodejs = super.nodejs-8_x;
      design = tags;
      set = "PPStyle";
    };

  wineNoGS = super.wineStaging.override { gstreamerSupport = false; };

  vim-samae = super.callPackage ./vim {};

  reaper-samae = super.callPackage ./reaper {};

  # Bug fixes:
  # VCVRack has a bug when used with Xmonad that makes the UI
  # crash almost immediately There's a workaround documented here
  # (https://github.com/VCVRack/Rack/issues/478#issuecomment-456174702) and it
  # requires applying a patch on the source before building.
  vcv-rack-xmonad = super.callPackage ./vcv-rack {};

  scientifica-font = super.callPackage ./scientifica-font {};
  curie-font = super.callPackage ./curie-font {};
  victor-mono = super.callPackage ./victor-mono {};

  ripmime = super.ripmime.override {
    stdenv = super.overrideCC super.stdenv super.gcc6;
  };

  minitube = super.libsForQt5.callPackage ./minitube {};

  # Originally from Mats Rauhala ®2018
  copy = super.writeScriptBin "copy" ''
    function clean() {
      sleep 10
      ${super.libnotify}/bin/notify-send -u low 'Clipboard cleaned'
      ${super.xclip}/bin/xclip -sel clipboard -i /dev/null
    }

    ${super.xclip}/bin/xclip -sel clipboard < /dev/stdin
    ${super.libnotify}/bin/notify-send -u low -t 10000 'Clipboard set'

    clean &
  '';
}