{ stdenv, lib
, fetchurl
, autoPatchelfHook
, alsaLib
, freetype
, glibc
, requireFile
}:

stdenv.mkDerivation rec {
  name = "decentsampler-${version}";

  version = "1.2.7";

  src = requireFile rec {
    name = "Decent_Sampler-${version}-Linux-x86_64.tar.gz";
    sha256 = "0wzz69xbqcp06bggpd7g21c2lzbm3ankflcxbqpb8qp3k3z5cx2m";
    message = ''
      Get ${name}, (linux version) from
      https://www.decentsamples.com/product/decent-sampler-plugin/

      And import it using:
      nix-prefetch-url file://<path/to>/${name}
    '';
  };

  nativeBuildInputs = [
    autoPatchelfHook
  ];

  buildInputs = [
    alsaLib
    freetype
    glibc
  ];

  sourceRoot = ".";

  installPhase = ''
    mkdir -p $out/lib/vst $out/lib/vst3
    install -m755 -D Decent_Sampler-${version}-Linux-x86_64/DecentSampler.so \
      $out/lib/vst/
    cp -r Decent_Sampler-${version}-Linux-x86_64/DecentSampler.vst3 $out/lib/vst3/
    chmod -R 0755 $out
  '';

  meta = with lib; {
    homepage = "https://www.decentsamples.com/product/decent-sampler-plugin/";
    description = "A FREE sampling plugin that allows you to play samples in the Decent Sampler format";
    platforms = platforms.linux;
  };
}