Add reaper to my collection

pkgs/default.nix

@@ -18,6 +18,8 @@ self: super:
 
   vim-samae = super.callPackage ./vim {};
 
+  reaper-samae = super.callPackage ./reaper {};
+
   # Bug fixes:
   # VCVRack has a bug when used with Xmonad that makes the UI
   # crash almost immediately There's a workaround documented here

pkgs/reaper/default.nix

@@ -0,0 +1,59 @@
+{ stdenv, fetchurl, autoPatchelfHook, makeWrapper
+, alsaLib, xorg
+, gnome3, gtk3, pango, gdk_pixbuf, cairo, glib, freetype
+, libpulseaudio, xdg_utils
+}:
+
+stdenv.mkDerivation rec {
+  name = "reaper-${version}";
+  version = "5.978";
+
+  src = fetchurl {
+    url = "https://www.reaper.fm/files/${stdenv.lib.versions.major version}.x/reaper${builtins.replaceStrings ["."] [""] version}_linux_x86_64.tar.xz";
+    sha256 = "0na7364zxxcic5mq4vaaj4va0g6rhwnwn9fg5gb421iba29ylmhg";
+  };
+
+  nativeBuildInputs = [ autoPatchelfHook makeWrapper ];
+
+  buildInputs = [
+    alsaLib
+
+    xorg.libX11
+    xorg.libXi
+
+    gdk_pixbuf
+    pango
+    cairo
+    glib
+    freetype
+
+    xdg_utils
+  ];
+
+  runtimeDependencies = [
+    gtk3
+  ];
+
+  dontBuild = true;
+
+  installPhase = ''
+    XDG_DATA_HOME="$out/share" ./install-reaper.sh \
+      --install $out/opt \
+      --integrate-user-desktop
+    rm $out/opt/REAPER/uninstall-reaper.sh
+
+    wrapProgram $out/opt/REAPER/reaper \
+      --prefix LD_LIBRARY_PATH : ${libpulseaudio}/lib
+
+    mkdir $out/bin
+    ln -s $out/opt/REAPER/reaper $out/bin/
+    ln -s $out/opt/REAPER/reamote-server $out/bin/
+  '';
+
+  meta = with stdenv.lib; {
+    description = "Digital audio workstation";
+    homepage = https://www.reaper.fm/;
+    license = licenses.unfree;
+    platforms = [ "x86_64-linux" ];
+  };
+}