diff --git a/pkgs/default.nix b/pkgs/default.nix
index 8434b60..5b76a27 100644
--- a/pkgs/default.nix
+++ b/pkgs/default.nix
@@ -31,6 +31,8 @@ self: super:
 
   mopidy-mpd-samae = super.callPackage ./mopidy-mpd {};
 
+  vcv-rack-samae = super.callPackage ./vcv-rack {};
+
   scientifica-font = super.callPackage ./scientifica-font {};
   curie-font = super.callPackage ./curie-font {};
   victor-mono = super.callPackage ./victor-mono {};
diff --git a/pkgs/vcv-rack/default.nix b/pkgs/vcv-rack/default.nix
new file mode 100644
index 0000000..5d4e4f2
--- /dev/null
+++ b/pkgs/vcv-rack/default.nix
@@ -0,0 +1,101 @@
+{ stdenv, makeWrapper, fetchzip, fetchFromGitHub, pkgconfig
+, alsaLib, curl, glew, glfw, gtk2-x11, jansson, libjack2, libXext, libXi
+, libzip, rtaudio, rtmidi, speex, libsamplerate }:
+
+let
+  # The package repo vendors some of the package dependencies as submodules.
+  # Others are downloaded with `make deps`. Due to previous issues with the
+  # `glfw` submodule (see above) and because we can not access the network when
+  # building in a sandbox, we fetch the dependency source manually.
+  pfft-source = fetchzip {
+    url = "https://bitbucket.org/jpommier/pffft/get/74d7261be17cf659d5930d4830609406bd7553e3.tar.gz";
+    sha256 = "084csgqa6f1a270bhybjayrh3mpyi2jimc87qkdgsqcp8ycsx1l1";
+  };
+  nanovg-source = fetchFromGitHub {
+    owner = "memononen";
+    repo = "nanovg";
+    rev = "1f9c8864fc556a1be4d4bf1d6bfe20cde25734b4";
+    sha256 = "08r15zrr6p1kxigxzxrg5rgya7wwbdx7d078r362qbkmws83wk27";
+  };
+  nanosvg-source = fetchFromGitHub {
+    owner = "memononen";
+    repo = "nanosvg";
+    rev = "25241c5a8f8451d41ab1b02ab2d865b01600d949";
+    sha256 = "114qgfmazsdl53rm4pgqif3gv8msdmfwi91lyc2jfadgzfd83xkg";
+  };
+  osdialog-source = fetchFromGitHub {
+    owner = "AndrewBelt";
+    repo = "osdialog";
+    rev = "e5db5de6444f4b2c4e1390c67b3efd718080c3da";
+    sha256 = "0iqxn1md053nl19hbjk8rqsdcmjwa5l5z0ci4fara77q43rc323i";
+  };
+  oui-blendish-source = fetchFromGitHub {
+    owner = "AndrewBelt";
+    repo = "oui-blendish";
+    rev = "79ec59e6bc7201017fc13a20c6e33380adca1660";
+    sha256 = "17kd0lh2x3x12bxkyhq6z8sg6vxln8m9qirf0basvcsmylr6rb64";
+  };
+in
+with stdenv.lib; stdenv.mkDerivation rec {
+  pname = "VCV-Rack";
+  version = "1.1.6";
+
+  src = fetchFromGitHub {
+    owner = "VCVRack";
+    repo = "Rack";
+    rev = "v${version}";
+    sha256 = "0ji64prr74qzxf5bx1sw022kbslx9nzll16lmk5in78hbl137b3i";
+  };
+
+  patches = [
+    ./rack-minimize-vendoring.patch
+  ];
+
+  prePatch = ''
+    # As we can't use `make dep` to set up the dependencies (as explained
+    # above), we do it here manually
+    mkdir -p dep/include
+
+    cp -r ${pfft-source} dep/jpommier-pffft-source
+    cp -r ${nanovg-source}/* dep/nanovg
+    cp -r ${nanosvg-source}/* dep/nanosvg
+    cp -r ${osdialog-source}/* dep/osdialog
+    cp -r ${oui-blendish-source}/* dep/oui-blendish
+
+    cp dep/jpommier-pffft-source/*.h dep/include
+    cp dep/nanosvg/**/*.h dep/include
+    cp dep/nanovg/src/*.h dep/include
+    cp dep/osdialog/*.h dep/include
+    cp dep/oui-blendish/*.h dep/include
+
+    substituteInPlace include/audio.hpp --replace "<RtAudio.h>" "<rtaudio/RtAudio.h>"
+    substituteInPlace compile.mk --replace "-march=nocona" ""
+  '';
+
+  enableParallelBuilding = true;
+
+  nativeBuildInputs = [ makeWrapper pkgconfig ];
+  buildInputs = [ alsaLib curl glew glfw gtk2-x11 jansson libjack2 libsamplerate libzip rtaudio rtmidi speex ];
+
+  buildFlags = [ "Rack" ];
+
+  installPhase = ''
+    install -D -m755 -t $out/bin Rack
+
+    mkdir -p $out/share/vcv-rack
+    cp -r res Core.json template.vcv LICENSE* cacert.pem $out/share/vcv-rack
+
+    # Override the default global resource file directory
+    wrapProgram $out/bin/Rack --add-flags "-s $out/share/vcv-rack"
+  '';
+
+  meta = with stdenv.lib; {
+    description = "Open-source virtual modular synthesizer";
+    homepage = "https://vcvrack.com/";
+    # The source is BSD-3 licensed, some of the art is CC-BY-NC 4.0 or under a
+    # no-derivatives clause
+    license = with licenses; [ bsd3 cc-by-nc-40 unfreeRedistributable ];
+    maintainers = with maintainers; [ moredread nathyong ];
+    platforms = platforms.linux;
+  };
+}
diff --git a/pkgs/vcv-rack/rack-minimize-vendoring.patch b/pkgs/vcv-rack/rack-minimize-vendoring.patch
new file mode 100644
index 0000000..d310d57
--- /dev/null
+++ b/pkgs/vcv-rack/rack-minimize-vendoring.patch
@@ -0,0 +1,13 @@
+diff -ru a/Makefile b/Makefile
+--- a/Makefile	1970-01-01 01:00:01.000000000 +0100
++++ b/Makefile	1970-01-01 01:00:01.000000000 +0100
+@@ -21,8 +21,8 @@
+ build/dep/osdialog/osdialog_gtk2.c.o: FLAGS += $(shell pkg-config --cflags gtk+-2.0)
+ 
+ 	LDFLAGS += -rdynamic \
+-		dep/lib/libGLEW.a dep/lib/libglfw3.a dep/lib/libjansson.a dep/lib/libcurl.a dep/lib/libssl.a dep/lib/libcrypto.a dep/lib/libzip.a dep/lib/libz.a dep/lib/libspeexdsp.a dep/lib/libsamplerate.a dep/lib/librtmidi.a dep/lib/librtaudio.a \
++		-lGLEW -lglfw -ljansson -lcurl -lssl -lcrypto -lzip -lz -lspeexdsp -lsamplerate -lrtmidi -lrtaudio \
+		-lpthread -lGL -ldl -lX11 -lasound -ljack \
+ 		$(shell pkg-config --libs gtk+-2.0)
+ 	TARGET := Rack
+ endif