overlays-personal/pkgs/default.nix

# This overlay provides a set of customized pkgs.

self: super:

let
  iosevkaTree = import (builtins.fetchTarball https://github.com/NixOS/nixpkgs/archive/dd2f026780399cf11c47fcf6085145b25b14307e.tar.gz) {};
  mopidyTree  = import (builtins.fetchTarball https://github.com/NixOS/nixpkgs/archive/d68db15912f6ff0f0082ed3825efae5098c77905.tar.gz) {};
in
{
  # Picked from 2019-09-26 tree
  # Delete this when it lands in main channel
  mopidy = mopidyTree.mopidy;

  # Picked from 2019-09-25 tree
  # replace iosevkaTree by super once it's in the main channel
  iosevka-hskl = iosevkaTree.iosevka.override {
    privateBuildPlan = {
      family = "Iosevka Samae";
      design = [
        "ss08" # Use Pragmata Pro Style
        "term" # Disable ligature/ligation
      ];
      slants = {
        upright = "normal";
        italic = "italic";
        oblique = "oblique";
      };
    };
    set = "Samae";
  };

  qutebrowserWE = super.qutebrowser.override { withWebEngineDefault = true; };

  wineNoGS = super.wineStaging.override { gstreamerSupport = false; };

  vim-samae = super.callPackage ./vim {};

  reaper-samae = super.callPackage ./reaper {};

  # Bug fixes:
  # VCVRack has a bug when used with Xmonad that makes the UI
  # crash almost immediately There's a workaround documented here
  # (https://github.com/VCVRack/Rack/issues/478#issuecomment-456174702) and it
  # requires applying a patch on the source before building.
  vcv-rack-xmonad = super.callPackage ./vcv-rack {};

  scientifica-font = super.callPackage ./scientifica-font {};
  curie-font = super.callPackage ./curie-font {};
  victor-mono = super.callPackage ./victor-mono {};

  ripmime = super.ripmime.override {
    stdenv = super.overrideCC super.stdenv super.gcc6;
  };

  # Originally from Mats Rauhala ®2018
  copy = super.writeScriptBin "copy" ''
    function clean() {
      sleep 10
      ${super.libnotify}/bin/notify-send -u low 'Clipboard cleaned'
      ${super.xclip}/bin/xclip -sel clipboard -i /dev/null
    }

    ${super.xclip}/bin/xclip -sel clipboard < /dev/stdin
    ${super.libnotify}/bin/notify-send -u low -t 10000 'Clipboard set'

    clean &
  '';
}