From 34ebec0853e2af787edc483ac51555a4d33900f5 Mon Sep 17 00:00:00 2001
From: Martin Potier <mpo.framacode@marvid.fr>
Date: Fri, 25 Mar 2016 12:09:01 +0100
Subject: [PATCH] Adding vim configuration

---
 configure                             |  19 ++
 vim/.vim/autoload/pathogen.vim        | 353 ++++++++++++++++++++++++++
 vim/.vim/bundle/VOoM                  |   1 +
 vim/.vim/bundle/vim-better-whitespace |   1 +
 vim/.vim/bundle/vim-colors-solarized  |   1 +
 vim/.vim/bundle/vim-fugitive          |   1 +
 vim/.vim/bundle/vim-obsession         |   1 +
 vim/.vim/bundle/vim-opencl            |   1 +
 vim/.vim/bundle/vim-surround          |   1 +
 vim/.vim/bundle/vim-systemd-syntax    |   1 +
 vim/.vim/bundle/vimtex                |   1 +
 vim/.vimrc                            | 109 ++++++++
 12 files changed, 490 insertions(+)
 create mode 100644 vim/.vim/autoload/pathogen.vim
 create mode 160000 vim/.vim/bundle/VOoM
 create mode 160000 vim/.vim/bundle/vim-better-whitespace
 create mode 160000 vim/.vim/bundle/vim-colors-solarized
 create mode 160000 vim/.vim/bundle/vim-fugitive
 create mode 160000 vim/.vim/bundle/vim-obsession
 create mode 160000 vim/.vim/bundle/vim-opencl
 create mode 160000 vim/.vim/bundle/vim-surround
 create mode 160000 vim/.vim/bundle/vim-systemd-syntax
 create mode 160000 vim/.vim/bundle/vimtex
 create mode 100644 vim/.vimrc

diff --git a/configure b/configure
index 5f647cd..7c38789 100755
--- a/configure
+++ b/configure
@@ -27,6 +27,25 @@ case $1 in
     stow -v scripts
     exit 0
     ;;
+  "vim"       )
+    echo "Installing vim config"
+    stow -v vim
+    cd ~/.vim/bundle
+    # Fetch plugins
+    git clone git://github.com/ntpeters/vim-better-whitespace.git
+    git clone git://github.com/altercation/vim-colors-solarized.git
+    git clone git://github.com/tpope/vim-fugitive.git
+    vim -u NONE -c "helptags vim-fugitive/doc" -c q
+    git clone git://github.com/tpope/vim-obsession.git
+    vim -u NONE -c "helptags vim-obsession/doc" -c q
+    git clone git://github.com/tpope/vim-surround.git
+    vim -u NONE -c "helptags vim-surround/doc" -c q
+    git clone git://github.com/petRUShka/vim-opencl.git
+    git clone git://github.com/Matt-Deacalion/vim-systemd-syntax.git
+    git clone git://github.com/lervag/vimtex.git
+    git clone git://github.com/vim-voom/VOoM.git
+    exit 0
+    ;;
   *             )
     echo "$1 cannot be installed…"
     exit 1
diff --git a/vim/.vim/autoload/pathogen.vim b/vim/.vim/autoload/pathogen.vim
new file mode 100644
index 0000000..59a75c1
--- /dev/null
+++ b/vim/.vim/autoload/pathogen.vim
@@ -0,0 +1,353 @@
+" pathogen.vim - path option manipulation
+" Maintainer:   Tim Pope <http://tpo.pe/>
+" Version:      2.4
+
+" Install in ~/.vim/autoload (or ~\vimfiles\autoload).
+"
+" For management of individually installed plugins in ~/.vim/bundle (or
+" ~\vimfiles\bundle), adding `execute pathogen#infect()` to the top of your
+" .vimrc is the only other setup necessary.
+"
+" The API is documented inline below.
+
+if exists("g:loaded_pathogen") || &cp
+  finish
+endif
+let g:loaded_pathogen = 1
+
+" Point of entry for basic default usage.  Give a relative path to invoke
+" pathogen#interpose() (defaults to "bundle/{}"), or an absolute path to invoke
+" pathogen#surround().  Curly braces are expanded with pathogen#expand():
+" "bundle/{}" finds all subdirectories inside "bundle" inside all directories
+" in the runtime path.
+function! pathogen#infect(...) abort
+  for path in a:0 ? filter(reverse(copy(a:000)), 'type(v:val) == type("")') : ['bundle/{}']
+    if path =~# '^\%({\=[$~\\/]\|{\=\w:[\\/]\).*[{}*]'
+      call pathogen#surround(path)
+    elseif path =~# '^\%([$~\\/]\|\w:[\\/]\)'
+      call s:warn('Change pathogen#infect('.string(path).') to pathogen#infect('.string(path.'/{}').')')
+      call pathogen#surround(path . '/{}')
+    elseif path =~# '[{}*]'
+      call pathogen#interpose(path)
+    else
+      call s:warn('Change pathogen#infect('.string(path).') to pathogen#infect('.string(path.'/{}').')')
+      call pathogen#interpose(path . '/{}')
+    endif
+  endfor
+  call pathogen#cycle_filetype()
+  if pathogen#is_disabled($MYVIMRC)
+    return 'finish'
+  endif
+  return ''
+endfunction
+
+" Split a path into a list.
+function! pathogen#split(path) abort
+  if type(a:path) == type([]) | return a:path | endif
+  if empty(a:path) | return [] | endif
+  let split = split(a:path,'\\\@<!\%(\\\\\)*\zs,')
+  return map(split,'substitute(v:val,''\\\([\\,]\)'',''\1'',"g")')
+endfunction
+
+" Convert a list to a path.
+function! pathogen#join(...) abort
+  if type(a:1) == type(1) && a:1
+    let i = 1
+    let space = ' '
+  else
+    let i = 0
+    let space = ''
+  endif
+  let path = ""
+  while i < a:0
+    if type(a:000[i]) == type([])
+      let list = a:000[i]
+      let j = 0
+      while j < len(list)
+        let escaped = substitute(list[j],'[,'.space.']\|\\[\,'.space.']\@=','\\&','g')
+        let path .= ',' . escaped
+        let j += 1
+      endwhile
+    else
+      let path .= "," . a:000[i]
+    endif
+    let i += 1
+  endwhile
+  return substitute(path,'^,','','')
+endfunction
+
+" Convert a list to a path with escaped spaces for 'path', 'tag', etc.
+function! pathogen#legacyjoin(...) abort
+  return call('pathogen#join',[1] + a:000)
+endfunction
+
+" Turn filetype detection off and back on again if it was already enabled.
+function! pathogen#cycle_filetype() abort
+  if exists('g:did_load_filetypes')
+    filetype off
+    filetype on
+  endif
+endfunction
+
+" Check if a bundle is disabled.  A bundle is considered disabled if its
+" basename or full name is included in the list g:pathogen_blacklist or the
+" comma delimited environment variable $VIMBLACKLIST.
+function! pathogen#is_disabled(path) abort
+  if a:path =~# '\~$'
+    return 1
+  endif
+  let sep = pathogen#slash()
+  let blacklist =
+        \ get(g:, 'pathogen_blacklist', get(g:, 'pathogen_disabled', [])) +
+        \ pathogen#split($VIMBLACKLIST)
+  if !empty(blacklist)
+    call map(blacklist, 'substitute(v:val, "[\\/]$", "", "")')
+  endif
+  return index(blacklist, fnamemodify(a:path, ':t')) != -1 || index(blacklist, a:path) != -1
+endfunction
+
+" Prepend the given directory to the runtime path and append its corresponding
+" after directory.  Curly braces are expanded with pathogen#expand().
+function! pathogen#surround(path) abort
+  let sep = pathogen#slash()
+  let rtp = pathogen#split(&rtp)
+  let path = fnamemodify(a:path, ':s?[\\/]\=$??')
+  let before = filter(pathogen#expand(path), '!pathogen#is_disabled(v:val)')
+  let after = filter(reverse(pathogen#expand(path, sep.'after')), '!pathogen#is_disabled(v:val[0:-7])')
+  call filter(rtp, 'index(before + after, v:val) == -1')
+  let &rtp = pathogen#join(before, rtp, after)
+  return &rtp
+endfunction
+
+" For each directory in the runtime path, add a second entry with the given
+" argument appended.  Curly braces are expanded with pathogen#expand().
+function! pathogen#interpose(name) abort
+  let sep = pathogen#slash()
+  let name = a:name
+  if has_key(s:done_bundles, name)
+    return ""
+  endif
+  let s:done_bundles[name] = 1
+  let list = []
+  for dir in pathogen#split(&rtp)
+    if dir =~# '\<after$'
+      let list += reverse(filter(pathogen#expand(dir[0:-6].name, sep.'after'), '!pathogen#is_disabled(v:val[0:-7])')) + [dir]
+    else
+      let list += [dir] + filter(pathogen#expand(dir.sep.name), '!pathogen#is_disabled(v:val)')
+    endif
+  endfor
+  let &rtp = pathogen#join(pathogen#uniq(list))
+  return 1
+endfunction
+
+let s:done_bundles = {}
+
+" Invoke :helptags on all non-$VIM doc directories in runtimepath.
+function! pathogen#helptags() abort
+  let sep = pathogen#slash()
+  for glob in pathogen#split(&rtp)
+    for dir in map(split(glob(glob), "\n"), 'v:val.sep."/doc/".sep')
+      if (dir)[0 : strlen($VIMRUNTIME)] !=# $VIMRUNTIME.sep && filewritable(dir) == 2 && !empty(split(glob(dir.'*.txt'))) && (!filereadable(dir.'tags') || filewritable(dir.'tags'))
+        silent! execute 'helptags' pathogen#fnameescape(dir)
+      endif
+    endfor
+  endfor
+endfunction
+
+command! -bar Helptags :call pathogen#helptags()
+
+" Execute the given command.  This is basically a backdoor for --remote-expr.
+function! pathogen#execute(...) abort
+  for command in a:000
+    execute command
+  endfor
+  return ''
+endfunction
+
+" Section: Unofficial
+
+function! pathogen#is_absolute(path) abort
+  return a:path =~# (has('win32') ? '^\%([\\/]\|\w:\)[\\/]\|^[~$]' : '^[/~$]')
+endfunction
+
+" Given a string, returns all possible permutations of comma delimited braced
+" alternatives of that string.  pathogen#expand('/{a,b}/{c,d}') yields
+" ['/a/c', '/a/d', '/b/c', '/b/d'].  Empty braces are treated as a wildcard
+" and globbed.  Actual globs are preserved.
+function! pathogen#expand(pattern, ...) abort
+  let after = a:0 ? a:1 : ''
+  if a:pattern =~# '{[^{}]\+}'
+    let [pre, pat, post] = split(substitute(a:pattern, '\(.\{-\}\){\([^{}]\+\)}\(.*\)', "\\1\001\\2\001\\3", ''), "\001", 1)
+    let found = map(split(pat, ',', 1), 'pre.v:val.post')
+    let results = []
+    for pattern in found
+      call extend(results, pathogen#expand(pattern))
+    endfor
+  elseif a:pattern =~# '{}'
+    let pat = matchstr(a:pattern, '^.*{}[^*]*\%($\|[\\/]\)')
+    let post = a:pattern[strlen(pat) : -1]
+    let results = map(split(glob(substitute(pat, '{}', '*', 'g')), "\n"), 'v:val.post')
+  else
+    let results = [a:pattern]
+  endif
+  let vf = pathogen#slash() . 'vimfiles'
+  call map(results, 'v:val =~# "\\*" ? v:val.after : isdirectory(v:val.vf.after) ? v:val.vf.after : isdirectory(v:val.after) ? v:val.after : ""')
+  return filter(results, '!empty(v:val)')
+endfunction
+
+" \ on Windows unless shellslash is set, / everywhere else.
+function! pathogen#slash() abort
+  return !exists("+shellslash") || &shellslash ? '/' : '\'
+endfunction
+
+function! pathogen#separator() abort
+  return pathogen#slash()
+endfunction
+
+" Convenience wrapper around glob() which returns a list.
+function! pathogen#glob(pattern) abort
+  let files = split(glob(a:pattern),"\n")
+  return map(files,'substitute(v:val,"[".pathogen#slash()."/]$","","")')
+endfunction
+
+" Like pathogen#glob(), only limit the results to directories.
+function! pathogen#glob_directories(pattern) abort
+  return filter(pathogen#glob(a:pattern),'isdirectory(v:val)')
+endfunction
+
+" Remove duplicates from a list.
+function! pathogen#uniq(list) abort
+  let i = 0
+  let seen = {}
+  while i < len(a:list)
+    if (a:list[i] ==# '' && exists('empty')) || has_key(seen,a:list[i])
+      call remove(a:list,i)
+    elseif a:list[i] ==# ''
+      let i += 1
+      let empty = 1
+    else
+      let seen[a:list[i]] = 1
+      let i += 1
+    endif
+  endwhile
+  return a:list
+endfunction
+
+" Backport of fnameescape().
+function! pathogen#fnameescape(string) abort
+  if exists('*fnameescape')
+    return fnameescape(a:string)
+  elseif a:string ==# '-'
+    return '\-'
+  else
+    return substitute(escape(a:string," \t\n*?[{`$\\%#'\"|!<"),'^[+>]','\\&','')
+  endif
+endfunction
+
+" Like findfile(), but hardcoded to use the runtimepath.
+function! pathogen#runtime_findfile(file,count) abort
+  let rtp = pathogen#join(1,pathogen#split(&rtp))
+  let file = findfile(a:file,rtp,a:count)
+  if file ==# ''
+    return ''
+  else
+    return fnamemodify(file,':p')
+  endif
+endfunction
+
+" Section: Deprecated
+
+function! s:warn(msg) abort
+  echohl WarningMsg
+  echomsg a:msg
+  echohl NONE
+endfunction
+
+" Prepend all subdirectories of path to the rtp, and append all 'after'
+" directories in those subdirectories.  Deprecated.
+function! pathogen#runtime_prepend_subdirectories(path) abort
+  call s:warn('Change pathogen#runtime_prepend_subdirectories('.string(a:path).') to pathogen#infect('.string(a:path.'/{}').')')
+  return pathogen#surround(a:path . pathogen#slash() . '{}')
+endfunction
+
+function! pathogen#incubate(...) abort
+  let name = a:0 ? a:1 : 'bundle/{}'
+  call s:warn('Change pathogen#incubate('.(a:0 ? string(a:1) : '').') to pathogen#infect('.string(name).')')
+  return pathogen#interpose(name)
+endfunction
+
+" Deprecated alias for pathogen#interpose().
+function! pathogen#runtime_append_all_bundles(...) abort
+  if a:0
+    call s:warn('Change pathogen#runtime_append_all_bundles('.string(a:1).') to pathogen#infect('.string(a:1.'/{}').')')
+  else
+    call s:warn('Change pathogen#runtime_append_all_bundles() to pathogen#infect()')
+  endif
+  return pathogen#interpose(a:0 ? a:1 . '/{}' : 'bundle/{}')
+endfunction
+
+if exists(':Vedit')
+  finish
+endif
+
+let s:vopen_warning = 0
+
+function! s:find(count,cmd,file,lcd)
+  let rtp = pathogen#join(1,pathogen#split(&runtimepath))
+  let file = pathogen#runtime_findfile(a:file,a:count)
+  if file ==# ''
+    return "echoerr 'E345: Can''t find file \"".a:file."\" in runtimepath'"
+  endif
+  if !s:vopen_warning
+    let s:vopen_warning = 1
+    let warning = '|echohl WarningMsg|echo "Install scriptease.vim to continue using :V'.a:cmd.'"|echohl NONE'
+  else
+    let warning = ''
+  endif
+  if a:lcd
+    let path = file[0:-strlen(a:file)-2]
+    execute 'lcd `=path`'
+    return a:cmd.' '.pathogen#fnameescape(a:file) . warning
+  else
+    return a:cmd.' '.pathogen#fnameescape(file) . warning
+  endif
+endfunction
+
+function! s:Findcomplete(A,L,P)
+  let sep = pathogen#slash()
+  let cheats = {
+        \'a': 'autoload',
+        \'d': 'doc',
+        \'f': 'ftplugin',
+        \'i': 'indent',
+        \'p': 'plugin',
+        \'s': 'syntax'}
+  if a:A =~# '^\w[\\/]' && has_key(cheats,a:A[0])
+    let request = cheats[a:A[0]].a:A[1:-1]
+  else
+    let request = a:A
+  endif
+  let pattern = substitute(request,'/\|\'.sep,'*'.sep,'g').'*'
+  let found = {}
+  for path in pathogen#split(&runtimepath)
+    let path = expand(path, ':p')
+    let matches = split(glob(path.sep.pattern),"\n")
+    call map(matches,'isdirectory(v:val) ? v:val.sep : v:val')
+    call map(matches,'expand(v:val, ":p")[strlen(path)+1:-1]')
+    for match in matches
+      let found[match] = 1
+    endfor
+  endfor
+  return sort(keys(found))
+endfunction
+
+command! -bar -bang -range=1 -nargs=1 -complete=customlist,s:Findcomplete Ve       :execute s:find(<count>,'edit<bang>',<q-args>,0)
+command! -bar -bang -range=1 -nargs=1 -complete=customlist,s:Findcomplete Vedit    :execute s:find(<count>,'edit<bang>',<q-args>,0)
+command! -bar -bang -range=1 -nargs=1 -complete=customlist,s:Findcomplete Vopen    :execute s:find(<count>,'edit<bang>',<q-args>,1)
+command! -bar -bang -range=1 -nargs=1 -complete=customlist,s:Findcomplete Vsplit   :execute s:find(<count>,'split',<q-args>,<bang>1)
+command! -bar -bang -range=1 -nargs=1 -complete=customlist,s:Findcomplete Vvsplit  :execute s:find(<count>,'vsplit',<q-args>,<bang>1)
+command! -bar -bang -range=1 -nargs=1 -complete=customlist,s:Findcomplete Vtabedit :execute s:find(<count>,'tabedit',<q-args>,<bang>1)
+command! -bar -bang -range=1 -nargs=1 -complete=customlist,s:Findcomplete Vpedit   :execute s:find(<count>,'pedit',<q-args>,<bang>1)
+command! -bar -bang -range=1 -nargs=1 -complete=customlist,s:Findcomplete Vread    :execute s:find(<count>,'read',<q-args>,<bang>1)
+
+" vim:set et sw=2 foldmethod=expr foldexpr=getline(v\:lnum)=~'^\"\ Section\:'?'>1'\:getline(v\:lnum)=~#'^fu'?'a1'\:getline(v\:lnum)=~#'^endf'?'s1'\:'=':
diff --git a/vim/.vim/bundle/VOoM b/vim/.vim/bundle/VOoM
new file mode 160000
index 0000000..4a26ad1
--- /dev/null
+++ b/vim/.vim/bundle/VOoM
@@ -0,0 +1 @@
+Subproject commit 4a26ad12d4c4030bd6a1bffaed980e60e348251a
diff --git a/vim/.vim/bundle/vim-better-whitespace b/vim/.vim/bundle/vim-better-whitespace
new file mode 160000
index 0000000..c77ffda
--- /dev/null
+++ b/vim/.vim/bundle/vim-better-whitespace
@@ -0,0 +1 @@
+Subproject commit c77ffda02d818e6f15d488ef96b11912a44e9285
diff --git a/vim/.vim/bundle/vim-colors-solarized b/vim/.vim/bundle/vim-colors-solarized
new file mode 160000
index 0000000..528a59f
--- /dev/null
+++ b/vim/.vim/bundle/vim-colors-solarized
@@ -0,0 +1 @@
+Subproject commit 528a59f26d12278698bb946f8fb82a63711eec21
diff --git a/vim/.vim/bundle/vim-fugitive b/vim/.vim/bundle/vim-fugitive
new file mode 160000
index 0000000..57afba5
--- /dev/null
+++ b/vim/.vim/bundle/vim-fugitive
@@ -0,0 +1 @@
+Subproject commit 57afba5bdd49b59d57485f90aa0cf3f3a6c47f63
diff --git a/vim/.vim/bundle/vim-obsession b/vim/.vim/bundle/vim-obsession
new file mode 160000
index 0000000..ad1ef9a
--- /dev/null
+++ b/vim/.vim/bundle/vim-obsession
@@ -0,0 +1 @@
+Subproject commit ad1ef9a0db9a03463b005b488fd27cb735317394
diff --git a/vim/.vim/bundle/vim-opencl b/vim/.vim/bundle/vim-opencl
new file mode 160000
index 0000000..a75693f
--- /dev/null
+++ b/vim/.vim/bundle/vim-opencl
@@ -0,0 +1 @@
+Subproject commit a75693fdb1526cf0f2f2d1a6bdc23d6537ac1b6f
diff --git a/vim/.vim/bundle/vim-surround b/vim/.vim/bundle/vim-surround
new file mode 160000
index 0000000..2d05440
--- /dev/null
+++ b/vim/.vim/bundle/vim-surround
@@ -0,0 +1 @@
+Subproject commit 2d05440ad23f97a7874ebd9b5de3a0e65d25d85c
diff --git a/vim/.vim/bundle/vim-systemd-syntax b/vim/.vim/bundle/vim-systemd-syntax
new file mode 160000
index 0000000..92f386d
--- /dev/null
+++ b/vim/.vim/bundle/vim-systemd-syntax
@@ -0,0 +1 @@
+Subproject commit 92f386d317c06ddb87c696d45c25c032eede3c03
diff --git a/vim/.vim/bundle/vimtex b/vim/.vim/bundle/vimtex
new file mode 160000
index 0000000..7bb6aa6
--- /dev/null
+++ b/vim/.vim/bundle/vimtex
@@ -0,0 +1 @@
+Subproject commit 7bb6aa630647f1e41f926f42d6fc59e8dd9fff38
diff --git a/vim/.vimrc b/vim/.vimrc
new file mode 100644
index 0000000..a45ac7d
--- /dev/null
+++ b/vim/.vimrc
@@ -0,0 +1,109 @@
+" Must have for vim
+set nocompatible
+
+" Display nbsp
+set listchars=tab:\|\ ,nbsp:·
+set list
+
+" Remap ESC on ,,
+map ,, <ESC>
+imap ,, <ESC>
+
+scriptencoding utf-8
+
+" Manage plugins
+call pathogen#infect()
+
+" Must be *after* pathogen
+filetype plugin indent on
+
+" Leader
+let mapleader=","
+nnoremap <leader>a :echo("\<leader\> works! It is set to <leader>")<CR>
+" let maplocalleader = "-"
+
+" Highlighting
+syntax enable
+if has('gui_running')
+    set background=light
+    set guifont=Inconsolata\ 16
+else
+    set background=light
+endif
+
+let g:solarized_termcolors=16
+colorscheme solarized
+
+" Set line numbering
+set number
+
+" Don't wrap lines, it's ugly
+set nowrap
+
+" Deal with tabs
+set softtabstop=2
+set tabstop=2    " 1 tab = 2 spaces
+set shiftwidth=2 " Indent with 2 spaces
+set expandtab    " Insert spaces instead of tabs
+
+" Set par as default wrapper
+set formatprg=par\ -w80
+
+" Set mouse on
+set mouse=a
+
+" Don't set timeout - this breaks the leader use
+set notimeout
+set ttimeout
+
+" Set filetype tex for tikz files
+au BufNewFile,BufRead *.mgs set filetype=mgs
+
+" Set filetype tex for tikz files
+au BufNewFile,BufRead *.tikz set filetype=tex
+
+" Set filetype Faust for DSP files
+au BufNewFile,BufRead *.dsp set filetype=faust
+
+" OCaml indentation
+let g:ocp_indent_vimfile = system("opam config var share")
+let g:ocp_indent_vimfile = substitute(g:ocp_indent_vimfile, '[\r\n]*$', '', '')
+let g:ocp_indent_vimfile = g:ocp_indent_vimfile . "/ocp-indent/vim/indent/ocaml.vim"
+
+autocmd FileType ocaml exec ":source " . g:ocp_indent_vimfile
+
+" For lusty-explorer
+set hidden
+
+" ack default config
+let g:ackprg = "ack -H --nocolor --nogroup --column"
+
+" place a marker and search
+nmap <leader>j mA:Ack <space>
+
+" place a marker and search the word under the cursor
+nmap <leader>ja mA:Ack "<C-r>=expand("<cword>")<cr>"
+nmap <leader>jA mA:Ack "<C-r>=expand("<cWORD>")<cr>"
+
+map <F12> :w<CR>:make -j 5<CR><CR><CR>
+map <space> za
+
+" Search for selected text, forwards or backwards.
+vnoremap <silent> * :<C-U>
+  \let old_reg=getreg('"')<Bar>let old_regtype=getregtype('"')<CR>
+  \gvy/<C-R><C-R>=substitute(
+  \escape(@", '/\.*$^~['), '\_s\+', '\\_s\\+', 'g')<CR><CR>
+  \gV:call setreg('"', old_reg, old_regtype)<CR>
+vnoremap <silent> # :<C-U>
+  \let old_reg=getreg('"')<Bar>let old_regtype=getregtype('"')<CR>
+  \gvy?<C-R><C-R>=substitute(
+  \escape(@", '?\.*$^~['), '\_s\+', '\\_s\\+', 'g')<CR><CR>
+  \gV:call setreg('"', old_reg, old_regtype)<CR>
+
+let &colorcolumn=join(range(81,999),",")
+
+" vimtex options
+let g:vimtex_fold_enabled=1
+let g:vimtex_fold_manual=1
+
+" vim:ai:et:sw=4:ts=4:sts=4:tw=78:fenc=utf-8:foldmethod=marker