mirror of
https://github.com/NixOS/nixos-hardware
synced 2024-11-16 16:09:40 +01:00
40 lines
1.5 KiB
Nix
40 lines
1.5 KiB
Nix
{ config, lib, pkgs, ... }:
|
|
|
|
let
|
|
cfg = config.hardware.framework.amd-7040;
|
|
in
|
|
{
|
|
imports = [
|
|
../common
|
|
../common/amd.nix
|
|
];
|
|
|
|
options = {
|
|
hardware.framework.amd-7040.preventWakeOnAC = lib.mkOption {
|
|
type = lib.types.bool;
|
|
default = false;
|
|
description = ''
|
|
Stop the system waking from suspend when the AC is plugged
|
|
in. The catch: it also disables waking from the keyboard.
|
|
|
|
See:
|
|
https://community.frame.work/t/tracking-framework-amd-ryzen-7040-series-lid-wakeup-behavior-feedback/39128/45
|
|
'';
|
|
};
|
|
};
|
|
|
|
config = {
|
|
# Newer kernel is better for amdgpu driver updates
|
|
# Requires at least 5.16 for working wi-fi and bluetooth (RZ616, kmod mt7922):
|
|
# https://wireless.wiki.kernel.org/en/users/drivers/mediatek
|
|
boot.kernelPackages = lib.mkIf (lib.versionOlder pkgs.linux.version "6.1") (lib.mkDefault pkgs.linuxPackages_latest);
|
|
|
|
# Workaround applied upstream in Linux >=6.7 (on BIOS 03.03)
|
|
# https://github.com/torvalds/linux/commit/a55bdad5dfd1efd4ed9ffe518897a21ca8e4e193
|
|
services.udev.extraRules = lib.mkIf (lib.versionOlder pkgs.linux.version "6.7" && cfg.preventWakeOnAC) ''
|
|
# Prevent wake when plugging in AC during suspend. Trade-off: keyboard wake disabled. See:
|
|
# https://community.frame.work/t/tracking-framework-amd-ryzen-7040-series-lid-wakeup-behavior-feedback/39128/45
|
|
ACTION=="add", SUBSYSTEM=="serio", DRIVERS=="atkbd", ATTR{power/wakeup}="disabled"
|
|
'';
|
|
};
|
|
}
|