apple-t2: remove ifd and cleanup drv

apple/t2/default.nix

@@ -24,7 +24,7 @@ let
 
   pipewirePackage = overrideAudioFiles pkgs.pipewire "spa/plugins/";
 
-  tiny-dfrPackage = pkgs.callPackage ./pkgs/tiny-dfr.nix { };
+  tiny-dfrPackage = pkgs.callPackage ./pkgs/tiny-dfr { };
 
   apple-set-os-loader-installer = pkgs.stdenv.mkDerivation {
     name = "apple-set-os-loader-installer-1.0";

apple/t2/pkgs/tiny-dfr.nix

@@ -1,51 +0,0 @@
-{ pkgs, fetchFromGitHub, rustPlatform, ... }:
-
-let
-  repo = fetchFromGitHub {
-      owner = "kekrby";
-      repo = "tiny-dfr";
-      rev = "8a5d413cb1dbe2a25b77a9e7f3cb5b9c88ef3ffb";
-      hash = "sha256-l4D7aePz/CYpkRorrvsgIYrvSzoZl59OGcFGJqqJftk=";
-  };
-
-in
-rustPlatform.buildRustPackage rec {
-  pname = "tiny-dfr";
-  version = repo.rev;
-
-  src = repo;
-
-  cargoLock.lockFile = "${src}/Cargo.lock";
-
-  nativeBuildInputs = with pkgs; [
-    pkg-config
-  ];
-
-  buildInputs = with pkgs; [
-    udev
-    glib
-    pango
-    cairo
-    gdk-pixbuf
-    libxml2
-    libinput
-  ];
-
-  postPatch = ''
-    substituteInPlace src/main.rs --replace "/usr/share/tiny-dfr/" "$out/share/tiny-dfr/"
-  '';
-
-  postInstall = ''
-    mkdir -p $out/etc $out/share
-
-    cp -r etc/udev $out/etc/
-    cp -r share/tiny-dfr $out/share/
-  '';
-
-  meta = with pkgs.lib; {
-    description = "The most basic dynamic function row daemon possible";
-    homepage = "https://github.com/kekrby/tiny-dfr";
-    license = with licenses; [ asl20 bsd3 cc0 isc lgpl21Plus mit mpl20 unicode-dfs-2016 asl20 asl20-llvm mit unlicense ];
-    maintainers = [];
-  };
-}

apple/t2/pkgs/tiny-dfr/default.nix

@@ -0,0 +1,62 @@
+{
+  lib,
+  rustPlatform,
+  fetchFromGitHub,
+
+  pkg-config,
+  cairo,
+  gdk-pixbuf,
+  glib,
+  libinput,
+  libxml2,
+  pango,
+  udev,
+}:
+let
+  src = fetchFromGitHub {
+    owner = "kekrby";
+    repo = "tiny-dfr";
+    rev = "8a5d413cb1dbe2a25b77a9e7f3cb5b9c88ef3ffb";
+    hash = "sha256-l4D7aePz/CYpkRorrvsgIYrvSzoZl59OGcFGJqqJftk=";
+  };
+in rustPlatform.buildRustPackage {
+  pname = "tiny-dfr";
+  version = src.rev;
+
+  inherit src;
+
+  cargoLock.lockFile = ./Cargo.lock;
+
+  nativeBuildInputs = [
+    pkg-config
+  ];
+
+  buildInputs = [
+    udev
+    glib
+    pango
+    cairo
+    gdk-pixbuf
+    libxml2
+    libinput
+  ];
+
+  postPatch = ''
+    substituteInPlace src/main.rs \
+      --replace-fail "/usr/share/tiny-dfr/" "$out/share/tiny-dfr/"
+  '';
+
+  postInstall = ''
+    mkdir -p $out/etc $out/share
+
+    cp -r etc/udev $out/etc/
+    cp -r share/tiny-dfr $out/share/
+  '';
+
+  meta = with lib; {
+    description = "The most basic dynamic function row daemon possible";
+    homepage = "https://github.com/kekrby/tiny-dfr";
+    license = with licenses; [ asl20 bsd3 cc0 isc lgpl21Plus mit mpl20 unicode-dfs-2016 asl20 asl20-llvm mit unlicense ];
+    maintainers = [];
+  };
+}