mirror of
https://github.com/nix-community/home-manager
synced 2024-11-16 16:19:44 +01:00
b3d5ea65d8
fastfetch: update example for JsonConfig settings
Using the present version of the example, trows an error:
JsonConfig Error: `display.binaryPrefix` has been renamed to
`display.size.binaryPrefix`. Sorry for another break change.
It occurs because of change in fastfetch 2.19 of JsonConfig - moving
`display.binaryPrefix` to `display.size.binaryPrefix`
To not confuse the users, this commit changes the example to fit
current standard
See <b3ac696312/CHANGELOG.md (L85)>
67 lines
1.6 KiB
Nix
67 lines
1.6 KiB
Nix
{ pkgs, lib, config, ... }:
|
|
|
|
let
|
|
inherit (lib) mkEnableOption mkPackageOption mkOption mkIf literalExpression;
|
|
|
|
cfg = config.programs.fastfetch;
|
|
|
|
jsonFormat = pkgs.formats.json { };
|
|
in {
|
|
meta.maintainers = with lib.hm.maintainers; [ afresquet ];
|
|
|
|
options.programs.fastfetch = {
|
|
enable = mkEnableOption "Fastfetch";
|
|
|
|
package = mkPackageOption pkgs "fastfetch" { };
|
|
|
|
settings = mkOption {
|
|
type = jsonFormat.type;
|
|
default = { };
|
|
example = literalExpression ''
|
|
{
|
|
logo = {
|
|
source = "nixos_small";
|
|
padding = {
|
|
right = 1;
|
|
};
|
|
};
|
|
display = {
|
|
size = {
|
|
binaryPrefix = "si";
|
|
};
|
|
color = "blue";
|
|
separator = " ";
|
|
};
|
|
modules = [
|
|
{
|
|
type = "datetime";
|
|
key = "Date";
|
|
format = "{1}-{3}-{11}";
|
|
}
|
|
{
|
|
type = "datetime";
|
|
key = "Time";
|
|
format = "{14}:{17}:{20}";
|
|
}
|
|
"break"
|
|
"player"
|
|
"media"
|
|
];
|
|
};
|
|
'';
|
|
description = ''
|
|
Configuration written to {file}`$XDG_CONFIG_HOME/fastfetch/config.jsonc`.
|
|
See <https://github.com/fastfetch-cli/fastfetch/wiki/Json-Schema>
|
|
for the documentation.
|
|
'';
|
|
};
|
|
};
|
|
|
|
config = mkIf cfg.enable {
|
|
home.packages = [ cfg.package ];
|
|
|
|
xdg.configFile."fastfetch/config.jsonc" = mkIf (cfg.settings != { }) {
|
|
source = jsonFormat.generate "config.jsonc" cfg.settings;
|
|
};
|
|
};
|
|
}
|