1
0
mirror of https://github.com/nix-community/home-manager synced 2024-06-26 00:18:30 +02:00
home-manager/modules/services/dropbox.nix
Emily 9f9e277b60 treewide: remove now-redundant lib.mdDoc calls
These (and the `*MD` functions apart from `literalMD`) are now no-ops
in nixpkgs and serve no purpose other than to add additional noise and
potentially mislead people into thinking unmarked DocBook documentation
will still be accepted.

Note that if backporting changes including documentation to 23.05,
the `mdDoc` calls will need to be re-added.

To reproduce this commit, run:

    $ NIX_PATH=nixpkgs=flake:nixpkgs/e7e69199f0372364a6106a1e735f68604f4c5a25 \
      nix shell nixpkgs#coreutils \
      -c find . -name '*.nix' \
      -exec nix run -- github:emilazy/nix-doc-munge/98dadf1f77351c2ba5dcb709a2a171d655f15099 \
      --strip {} +
    $ ./format
2023-07-17 18:49:09 +01:00

83 lines
2.3 KiB
Nix

{ config, lib, pkgs, ... }:
with lib;
let
cfg = config.services.dropbox;
baseDir = ".dropbox-hm";
dropboxCmd = "${pkgs.dropbox-cli}/bin/dropbox";
homeBaseDir = "${config.home.homeDirectory}/${baseDir}";
in {
meta.maintainers = [ maintainers.eyjhb ];
options = {
services.dropbox = {
enable = mkEnableOption "Dropbox daemon";
path = mkOption {
type = types.path;
default = "${config.home.homeDirectory}/Dropbox";
defaultText =
literalExpression ''"''${config.home.homeDirectory}/Dropbox"'';
apply = toString; # Prevent copies to Nix store.
description = "Where to put the Dropbox directory.";
};
};
};
config = mkIf cfg.enable {
assertions = [
(lib.hm.assertions.assertPlatform "services.dropbox" pkgs
lib.platforms.linux)
];
home.packages = [ pkgs.dropbox-cli ];
systemd.user.services.dropbox = {
Unit = { Description = "dropbox"; };
Install = { WantedBy = [ "default.target" ]; };
Service = {
Environment = [ "HOME=${homeBaseDir}" "DISPLAY=" ];
Type = "forking";
PIDFile = "${homeBaseDir}/.dropbox/dropbox.pid";
Restart = "on-failure";
PrivateTmp = true;
ProtectSystem = "full";
Nice = 10;
ExecReload = "${pkgs.coreutils}/bin/kill -HUP $MAINPID";
ExecStop = "${dropboxCmd} stop";
ExecStart = toString (pkgs.writeShellScript "dropbox-start" ''
# ensure we have the dirs we need
$DRY_RUN_CMD ${pkgs.coreutils}/bin/mkdir $VERBOSE_ARG -p \
${homeBaseDir}/{.dropbox,.dropbox-dist,Dropbox}
# symlink them as needed
if [[ ! -d ${config.home.homeDirectory}/.dropbox ]]; then
$DRY_RUN_CMD ${pkgs.coreutils}/bin/ln $VERBOSE_ARG -s \
${homeBaseDir}/.dropbox ${config.home.homeDirectory}/.dropbox
fi
if [[ ! -d ${escapeShellArg cfg.path} ]]; then
$DRY_RUN_CMD ${pkgs.coreutils}/bin/ln $VERBOSE_ARG -s \
${homeBaseDir}/Dropbox ${escapeShellArg cfg.path}
fi
# get the dropbox bins if needed
if [[ ! -f $HOME/.dropbox-dist/VERSION ]]; then
${pkgs.coreutils}/bin/yes | ${dropboxCmd} update
fi
${dropboxCmd} start
'');
};
};
};
}