mirror of
https://github.com/nix-community/home-manager
synced 2024-09-12 06:16:33 +02:00
These (and the `*MD` functions apart from `literalMD`) are now no-ops in nixpkgs and serve no purpose other than to add additional noise and potentially mislead people into thinking unmarked DocBook documentation will still be accepted. Note that if backporting changes including documentation to 23.05, the `mdDoc` calls will need to be re-added. To reproduce this commit, run: $ NIX_PATH=nixpkgs=flake:nixpkgs/e7e69199f0372364a6106a1e735f68604f4c5a25 \ nix shell nixpkgs#coreutils \ -c find . -name '*.nix' \ -exec nix run -- github:emilazy/nix-doc-munge/98dadf1f77351c2ba5dcb709a2a171d655f15099 \ --strip {} + $ ./format
85 lines
2.1 KiB
Nix
85 lines
2.1 KiB
Nix
{ config, lib, pkgs, ... }:
|
|
|
|
with lib;
|
|
|
|
let
|
|
|
|
cfg = config.programs.zathura;
|
|
|
|
formatLine = n: v:
|
|
let
|
|
formatValue = v:
|
|
if isBool v then (if v then "true" else "false") else toString v;
|
|
in ''set ${n} "${formatValue v}"'';
|
|
|
|
formatMapLine = n: v: "map ${n} ${toString v}";
|
|
|
|
in {
|
|
meta.maintainers = [ maintainers.rprospero ];
|
|
|
|
options.programs.zathura = {
|
|
enable = mkEnableOption ''
|
|
Zathura, a highly customizable and functional document viewer
|
|
focused on keyboard interaction'';
|
|
|
|
package = mkOption {
|
|
type = types.package;
|
|
default = pkgs.zathura;
|
|
defaultText = "pkgs.zathura";
|
|
description = "The Zathura package to use";
|
|
};
|
|
|
|
options = mkOption {
|
|
default = { };
|
|
type = with types; attrsOf (either str (either bool int));
|
|
description = ''
|
|
Add {option}`:set` command options to zathura and make
|
|
them permanent. See
|
|
{manpage}`zathurarc(5)`
|
|
for the full list of options.
|
|
'';
|
|
example = {
|
|
default-bg = "#000000";
|
|
default-fg = "#FFFFFF";
|
|
};
|
|
};
|
|
|
|
mappings = mkOption {
|
|
default = { };
|
|
type = with types; attrsOf str;
|
|
description = ''
|
|
Add {option}`:map` mappings to zathura and make
|
|
them permanent. See
|
|
{manpage}`zathurarc(5)`
|
|
for the full list of possible mappings.
|
|
|
|
You can create a mode-specific mapping by specifying the mode before the key:
|
|
`"[normal] <C-b>" = "scroll left";`
|
|
'';
|
|
example = {
|
|
D = "toggle_page_mode";
|
|
"<Right>" = "navigate next";
|
|
"[fullscreen] <C-i>" = "zoom in";
|
|
};
|
|
};
|
|
|
|
extraConfig = mkOption {
|
|
type = types.lines;
|
|
default = "";
|
|
description = ''
|
|
Additional commands for zathura that will be added to the
|
|
{file}`zathurarc` file.
|
|
'';
|
|
};
|
|
};
|
|
|
|
config = mkIf cfg.enable {
|
|
home.packages = [ cfg.package ];
|
|
|
|
xdg.configFile."zathura/zathurarc".text = concatStringsSep "\n" ([ ]
|
|
++ optional (cfg.extraConfig != "") cfg.extraConfig
|
|
++ mapAttrsToList formatLine cfg.options
|
|
++ mapAttrsToList formatMapLine cfg.mappings) + "\n";
|
|
};
|
|
}
|