mirror of
https://github.com/nix-community/home-manager
synced 2024-09-12 06:16:33 +02:00
These (and the `*MD` functions apart from `literalMD`) are now no-ops in nixpkgs and serve no purpose other than to add additional noise and potentially mislead people into thinking unmarked DocBook documentation will still be accepted. Note that if backporting changes including documentation to 23.05, the `mdDoc` calls will need to be re-added. To reproduce this commit, run: $ NIX_PATH=nixpkgs=flake:nixpkgs/e7e69199f0372364a6106a1e735f68604f4c5a25 \ nix shell nixpkgs#coreutils \ -c find . -name '*.nix' \ -exec nix run -- github:emilazy/nix-doc-munge/98dadf1f77351c2ba5dcb709a2a171d655f15099 \ --strip {} + $ ./format
102 lines
2.3 KiB
Nix
102 lines
2.3 KiB
Nix
{ config, lib, pkgs, ... }:
|
|
|
|
with lib;
|
|
let
|
|
|
|
cfg = config.programs.mcfly;
|
|
|
|
in {
|
|
meta.maintainers = [ ];
|
|
|
|
imports = [
|
|
(mkChangedOptionModule # \
|
|
[ "programs" "mcfly" "enableFuzzySearch" ] # \
|
|
[ "programs" "mcfly" "fuzzySearchFactor" ] # \
|
|
(config:
|
|
let
|
|
value =
|
|
getAttrFromPath [ "programs" "mcfly" "enableFuzzySearch" ] config;
|
|
in if value then 2 else 0))
|
|
];
|
|
|
|
options.programs.mcfly = {
|
|
enable = mkEnableOption "mcfly";
|
|
|
|
keyScheme = mkOption {
|
|
type = types.enum [ "emacs" "vim" ];
|
|
default = "emacs";
|
|
description = ''
|
|
Key scheme to use.
|
|
'';
|
|
};
|
|
|
|
enableLightTheme = mkOption {
|
|
default = false;
|
|
type = types.bool;
|
|
description = ''
|
|
Whether to enable light mode theme.
|
|
'';
|
|
};
|
|
|
|
fuzzySearchFactor = mkOption {
|
|
default = 0;
|
|
type = types.ints.unsigned;
|
|
description = ''
|
|
Whether to enable fuzzy searching.
|
|
0 is off; higher numbers weight toward shorter matches.
|
|
Values in the 2-5 range get good results so far.
|
|
'';
|
|
};
|
|
|
|
enableBashIntegration = mkOption {
|
|
default = true;
|
|
type = types.bool;
|
|
description = ''
|
|
Whether to enable Bash integration.
|
|
'';
|
|
};
|
|
|
|
enableZshIntegration = mkOption {
|
|
default = true;
|
|
type = types.bool;
|
|
description = ''
|
|
Whether to enable Zsh integration.
|
|
'';
|
|
};
|
|
|
|
enableFishIntegration = mkOption {
|
|
default = true;
|
|
type = types.bool;
|
|
description = ''
|
|
Whether to enable Fish integration.
|
|
'';
|
|
};
|
|
};
|
|
|
|
config = mkIf cfg.enable (mkMerge [
|
|
{
|
|
home.packages = [ pkgs.mcfly ];
|
|
|
|
programs.bash.initExtra = mkIf cfg.enableBashIntegration ''
|
|
eval "$(${pkgs.mcfly}/bin/mcfly init bash)"
|
|
'';
|
|
|
|
programs.zsh.initExtra = mkIf cfg.enableZshIntegration ''
|
|
eval "$(${pkgs.mcfly}/bin/mcfly init zsh)"
|
|
'';
|
|
|
|
programs.fish.shellInit = mkIf cfg.enableFishIntegration ''
|
|
${pkgs.mcfly}/bin/mcfly init fish | source
|
|
'';
|
|
|
|
home.sessionVariables.MCFLY_KEY_SCHEME = cfg.keyScheme;
|
|
}
|
|
|
|
(mkIf cfg.enableLightTheme { home.sessionVariables.MCFLY_LIGHT = "TRUE"; })
|
|
|
|
(mkIf (cfg.fuzzySearchFactor > 0) {
|
|
home.sessionVariables.MCFLY_FUZZY = cfg.fuzzySearchFactor;
|
|
})
|
|
]);
|
|
}
|