mirror of
https://github.com/nix-community/home-manager
synced 2024-09-12 06:16:33 +02:00
These (and the `*MD` functions apart from `literalMD`) are now no-ops in nixpkgs and serve no purpose other than to add additional noise and potentially mislead people into thinking unmarked DocBook documentation will still be accepted. Note that if backporting changes including documentation to 23.05, the `mdDoc` calls will need to be re-added. To reproduce this commit, run: $ NIX_PATH=nixpkgs=flake:nixpkgs/e7e69199f0372364a6106a1e735f68604f4c5a25 \ nix shell nixpkgs#coreutils \ -c find . -name '*.nix' \ -exec nix run -- github:emilazy/nix-doc-munge/98dadf1f77351c2ba5dcb709a2a171d655f15099 \ --strip {} + $ ./format
64 lines
1.4 KiB
Nix
64 lines
1.4 KiB
Nix
{ config, lib, pkgs, ... }:
|
|
|
|
with lib;
|
|
|
|
let
|
|
|
|
cfg = config.programs.lsd;
|
|
|
|
yamlFormat = pkgs.formats.yaml { };
|
|
|
|
aliases = {
|
|
ls = "${pkgs.lsd}/bin/lsd";
|
|
ll = "${pkgs.lsd}/bin/lsd -l";
|
|
la = "${pkgs.lsd}/bin/lsd -A";
|
|
lt = "${pkgs.lsd}/bin/lsd --tree";
|
|
lla = "${pkgs.lsd}/bin/lsd -lA";
|
|
llt = "${pkgs.lsd}/bin/lsd -l --tree";
|
|
};
|
|
|
|
in {
|
|
meta.maintainers = [ ];
|
|
|
|
options.programs.lsd = {
|
|
enable = mkEnableOption "lsd";
|
|
|
|
enableAliases = mkOption {
|
|
default = false;
|
|
type = types.bool;
|
|
description = ''
|
|
Whether to enable recommended lsd aliases.
|
|
'';
|
|
};
|
|
|
|
settings = mkOption {
|
|
type = yamlFormat.type;
|
|
default = { };
|
|
example = {
|
|
date = "relative";
|
|
ignore-globs = [ ".git" ".hg" ];
|
|
};
|
|
description = ''
|
|
Configuration written to
|
|
{file}`$XDG_CONFIG_HOME/lsd/config.yaml`. See
|
|
<https://github.com/Peltoche/lsd#config-file-content>
|
|
for supported values.
|
|
'';
|
|
};
|
|
};
|
|
|
|
config = mkIf cfg.enable {
|
|
home.packages = [ pkgs.lsd ];
|
|
|
|
programs.bash.shellAliases = mkIf cfg.enableAliases aliases;
|
|
|
|
programs.zsh.shellAliases = mkIf cfg.enableAliases aliases;
|
|
|
|
programs.fish.shellAliases = mkIf cfg.enableAliases aliases;
|
|
|
|
xdg.configFile."lsd/config.yaml" = mkIf (cfg.settings != { }) {
|
|
source = yamlFormat.generate "lsd-config" cfg.settings;
|
|
};
|
|
};
|
|
}
|