mirror of
https://github.com/nix-community/home-manager
synced 2024-09-12 06:16:33 +02:00
These (and the `*MD` functions apart from `literalMD`) are now no-ops in nixpkgs and serve no purpose other than to add additional noise and potentially mislead people into thinking unmarked DocBook documentation will still be accepted. Note that if backporting changes including documentation to 23.05, the `mdDoc` calls will need to be re-added. To reproduce this commit, run: $ NIX_PATH=nixpkgs=flake:nixpkgs/e7e69199f0372364a6106a1e735f68604f4c5a25 \ nix shell nixpkgs#coreutils \ -c find . -name '*.nix' \ -exec nix run -- github:emilazy/nix-doc-munge/98dadf1f77351c2ba5dcb709a2a171d655f15099 \ --strip {} + $ ./format
61 lines
1.6 KiB
Nix
61 lines
1.6 KiB
Nix
{ config, lib, pkgs, ... }:
|
|
|
|
with lib;
|
|
|
|
let
|
|
|
|
cfg = config.programs.lazygit;
|
|
|
|
yamlFormat = pkgs.formats.yaml { };
|
|
|
|
inherit (pkgs.stdenv.hostPlatform) isDarwin;
|
|
|
|
in {
|
|
meta.maintainers = [ hm.maintainers.kalhauge ];
|
|
|
|
options.programs.lazygit = {
|
|
enable = mkEnableOption "lazygit, a simple terminal UI for git commands";
|
|
|
|
package = mkPackageOption pkgs "lazygit" { };
|
|
|
|
settings = mkOption {
|
|
type = yamlFormat.type;
|
|
default = { };
|
|
defaultText = literalExpression "{ }";
|
|
example = literalExpression ''
|
|
{
|
|
gui.theme = {
|
|
lightTheme = true;
|
|
activeBorderColor = [ "blue" "bold" ];
|
|
inactiveBorderColor = [ "black" ];
|
|
selectedLineBgColor = [ "default" ];
|
|
};
|
|
}
|
|
'';
|
|
description = ''
|
|
Configuration written to
|
|
{file}`$XDG_CONFIG_HOME/lazygit/config.yml`
|
|
on Linux or on Darwin if [](#opt-xdg.enable) is set, otherwise
|
|
{file}`~/Library/Application Support/lazygit/config.yml`.
|
|
See
|
|
<https://github.com/jesseduffield/lazygit/blob/master/docs/Config.md>
|
|
for supported values.
|
|
'';
|
|
};
|
|
};
|
|
|
|
config = mkIf cfg.enable {
|
|
home.packages = [ cfg.package ];
|
|
|
|
home.file."Library/Application Support/lazygit/config.yml" =
|
|
mkIf (cfg.settings != { } && (isDarwin && !config.xdg.enable)) {
|
|
source = yamlFormat.generate "lazygit-config" cfg.settings;
|
|
};
|
|
|
|
xdg.configFile."lazygit/config.yml" =
|
|
mkIf (cfg.settings != { } && !(isDarwin && !config.xdg.enable)) {
|
|
source = yamlFormat.generate "lazygit-config" cfg.settings;
|
|
};
|
|
};
|
|
}
|