mirror of
https://github.com/nix-community/home-manager
synced 2024-11-18 09:09:45 +01:00
c7592b747b
Currently, dot directories and XDG base directories are used inconsistently in the Home Manager option declarations. This creates ambiguity for the user as to where the location of the file should be albeit this is rarely encountered in practice as it is sufficient to read upstream documentation. The rationale is to make declarations consistent and make a clear distinction between hardcoded and modular specifications. References to ~/.config in relevant nixpkgs modules were untouched as the location is hardcoded upstream[1]. Furthermore, modules of programs which do not follow XDG specifications were also untouched. Generalization of tilde(~) expansions to $HOME were also considered, however there isn't sufficient rationale despite the use of $HOME being more universal. The expansion is standardized in POSIX[2] and is essentially portable across all shells, thus there is no pragmatic value to introducing the change. [1] https://github.com/nixos/nixpkgs/blob/master/pkgs/top-level/impure.nix [2] https://pubs.opengroup.org/onlinepubs/009695399/utilities/xcu_chap02.html#tag_02_06_01
56 lines
1.5 KiB
Nix
56 lines
1.5 KiB
Nix
{ config, lib, pkgs, ... }:
|
|
|
|
with lib;
|
|
|
|
let
|
|
|
|
cfg = config.programs.lazygit;
|
|
|
|
yamlFormat = pkgs.formats.yaml { };
|
|
|
|
inherit (pkgs.stdenv.hostPlatform) isDarwin;
|
|
|
|
in {
|
|
meta.maintainers = [ maintainers.kalhauge ];
|
|
|
|
options.programs.lazygit = {
|
|
enable = mkEnableOption "lazygit, a simple terminal UI for git commands";
|
|
|
|
settings = mkOption {
|
|
type = yamlFormat.type;
|
|
default = { };
|
|
defaultText = literalExpression "{ }";
|
|
example = literalExpression ''
|
|
{
|
|
gui.theme = {
|
|
lightTheme = true;
|
|
activeBorderColor = [ "blue" "bold" ];
|
|
inactiveBorderColor = [ "black" ];
|
|
selectedLineBgColor = [ "default" ];
|
|
};
|
|
}
|
|
'';
|
|
description = ''
|
|
Configuration written to
|
|
<filename>$XDG_CONFIG_HOME/lazygit/config.yml</filename> on Linux
|
|
or <filename>~/Library/Application Support/lazygit/config.yml</filename> on Darwin. See
|
|
<link xlink:href="https://github.com/jesseduffield/lazygit/blob/master/docs/Config.md"/>
|
|
for supported values.
|
|
'';
|
|
};
|
|
};
|
|
|
|
config = mkIf cfg.enable {
|
|
home.packages = [ pkgs.lazygit ];
|
|
|
|
home.file."Library/Application Support/lazygit/config.yml" =
|
|
mkIf (cfg.settings != { } && isDarwin) {
|
|
source = yamlFormat.generate "lazygit-config" cfg.settings;
|
|
};
|
|
|
|
xdg.configFile."lazygit/config.yml" =
|
|
mkIf (cfg.settings != { } && !isDarwin) {
|
|
source = yamlFormat.generate "lazygit-config" cfg.settings;
|
|
};
|
|
};
|
|
}
|