mirror of
https://github.com/nix-community/home-manager
synced 2024-11-24 03:59:46 +01:00
6e4b9af080
This change makes use of the `extend` function inside `lib` to inject a new `hm` field containing the Home Manager library functions. This simplifies use of the Home Manager library in the modules and reduces the risk of accidental infinite recursion. PR #994
62 lines
1.3 KiB
Nix
62 lines
1.3 KiB
Nix
{ configuration
|
||
, pkgs
|
||
, lib ? pkgs.stdenv.lib
|
||
|
||
# Whether to check that each option has a matching declaration.
|
||
, check ? true
|
||
}:
|
||
|
||
with lib;
|
||
|
||
let
|
||
|
||
collectFailed = cfg:
|
||
map (x: x.message) (filter (x: !x.assertion) cfg.assertions);
|
||
|
||
showWarnings = res:
|
||
let
|
||
f = w: x: builtins.trace "[1;31mwarning: ${w}[0m" x;
|
||
in
|
||
fold f res res.config.warnings;
|
||
|
||
extendedLib = import ./lib/stdlib-extended.nix pkgs.lib;
|
||
|
||
hmModules =
|
||
import ./modules.nix {
|
||
inherit check pkgs;
|
||
lib = extendedLib;
|
||
};
|
||
|
||
rawModule = extendedLib.evalModules {
|
||
modules = [ configuration ] ++ hmModules;
|
||
specialArgs = {
|
||
modulesPath = builtins.toString ./.;
|
||
};
|
||
};
|
||
|
||
module = showWarnings (
|
||
let
|
||
failed = collectFailed rawModule.config;
|
||
failedStr = concatStringsSep "\n" (map (x: "- ${x}") failed);
|
||
in
|
||
if failed == []
|
||
then rawModule
|
||
else throw "\nFailed assertions:\n${failedStr}"
|
||
);
|
||
|
||
in
|
||
|
||
{
|
||
inherit (module) options config;
|
||
|
||
activationPackage = module.config.home.activationPackage;
|
||
|
||
# For backwards compatibility. Please use activationPackage instead.
|
||
activation-script = module.config.home.activationPackage;
|
||
|
||
newsDisplay = rawModule.config.news.display;
|
||
newsEntries =
|
||
sort (a: b: a.time > b.time) (
|
||
filter (a: a.condition) rawModule.config.news.entries
|
||
);
|
||
}
|