mirror of
https://github.com/nix-community/home-manager
synced 2024-12-27 12:19:48 +01:00
9f9e277b60
These (and the `*MD` functions apart from `literalMD`) are now no-ops
in nixpkgs and serve no purpose other than to add additional noise and
potentially mislead people into thinking unmarked DocBook documentation
will still be accepted.
Note that if backporting changes including documentation to 23.05,
the `mdDoc` calls will need to be re-added.
To reproduce this commit, run:
$ NIX_PATH=nixpkgs=flake:nixpkgs/e7e69199f0372364a6106a1e735f68604f4c5a25 \
nix shell nixpkgs#coreutils \
-c find . -name '*.nix' \
-exec nix run -- github:emilazy/nix-doc-munge/98dadf1f77351c2ba5dcb709a2a171d655f15099 \
--strip {} +
$ ./format
85 lines
2.3 KiB
Nix
85 lines
2.3 KiB
Nix
{ config, lib, pkgs, ... }:
|
|
|
|
with lib;
|
|
|
|
let
|
|
cfg = config.programs.pistol;
|
|
|
|
configFile = concatStringsSep "\n" (map ({ fpath, mime, command }:
|
|
if fpath == "" then "${mime} ${command}" else "fpath ${fpath} ${command}")
|
|
cfg.associations);
|
|
|
|
association = types.submodule {
|
|
options = {
|
|
command = mkOption {
|
|
type = types.str;
|
|
description = "Preview command for files matched by this association.";
|
|
};
|
|
|
|
fpath = mkOption {
|
|
type = types.str;
|
|
default = "";
|
|
description = "File path regex that this association should match.";
|
|
};
|
|
|
|
mime = mkOption {
|
|
type = types.str;
|
|
default = "";
|
|
description = "Mime type regex that this association should match.";
|
|
};
|
|
};
|
|
};
|
|
in {
|
|
imports = [
|
|
(mkRemovedOptionModule [ "programs" "pistol" "config" ]
|
|
"Pistol is now configured with programs.pistol.associations.")
|
|
];
|
|
|
|
meta.maintainers = [ hm.maintainers.mtoohey ];
|
|
|
|
options.programs.pistol = {
|
|
enable = mkEnableOption "file previewer for terminal file managers";
|
|
|
|
associations = mkOption {
|
|
type = types.listOf association;
|
|
default = [ ];
|
|
example = literalExpression ''
|
|
[
|
|
{ mime = "application/json"; command = "bat %pistol-filename%"; }
|
|
{ mime = "application/*"; command = "hexyl %pistol-filename%"; }
|
|
{ fpath = ".*.md$"; command = "sh: bat --paging=never --color=always %pistol-filename% | head -8"; }
|
|
]
|
|
'';
|
|
description = ''
|
|
Associations written to the Pistol configuration at
|
|
{file}`$XDG_CONFIG_HOME/pistol/pistol.conf`.
|
|
'';
|
|
};
|
|
|
|
};
|
|
|
|
config = mkIf cfg.enable (mkMerge [
|
|
{
|
|
assertions = [{
|
|
assertion = all ({ fpath, mime, ... }:
|
|
(fpath != "" && mime == "") || (fpath == "" && mime != ""))
|
|
cfg.associations;
|
|
message = ''
|
|
Each entry in programs.pistol.associations must contain exactly one
|
|
of fpath or mime.
|
|
'';
|
|
}];
|
|
|
|
home.packages = [ pkgs.pistol ];
|
|
}
|
|
|
|
(mkIf (cfg.associations != [ ] && pkgs.stdenv.hostPlatform.isDarwin) {
|
|
home.file."Library/Application Support/pistol/pistol.conf".text =
|
|
configFile;
|
|
})
|
|
|
|
(mkIf (cfg.associations != [ ] && !pkgs.stdenv.hostPlatform.isDarwin) {
|
|
xdg.configFile."pistol/pistol.conf".text = configFile;
|
|
})
|
|
]);
|
|
}
|