mirror of
https://github.com/nix-community/home-manager
synced 2024-11-23 19:49:45 +01:00
5f433eb164
Before, loading a module would be guarded by an optional platform condition. This made it possible to avoid loading and evaluating a module if it did not support the host platform. Unfortunately, this made it impossible to share a single configuration between GNU/Linux and Darwin hosts, which some wish to do. This removes the conditional load and instead inserts host platform assertions in the modules that are platform specific. Fixes #1906
81 lines
2 KiB
Nix
81 lines
2 KiB
Nix
{ config, lib, pkgs, ... }:
|
|
|
|
with lib;
|
|
|
|
let
|
|
|
|
cfg = config.services.hound;
|
|
|
|
jsonFormat = pkgs.formats.json { };
|
|
|
|
configFile = jsonFormat.generate "hound-config.json" {
|
|
max-concurrent-indexers = cfg.maxConcurrentIndexers;
|
|
dbpath = cfg.databasePath;
|
|
repos = cfg.repositories;
|
|
health-check-url = "/healthz";
|
|
};
|
|
|
|
houndOptions = [ "--addr ${cfg.listenAddress}" "--conf ${configFile}" ];
|
|
|
|
in {
|
|
meta.maintainers = [ maintainers.adisbladis ];
|
|
|
|
options.services.hound = {
|
|
enable = mkEnableOption "hound";
|
|
|
|
maxConcurrentIndexers = mkOption {
|
|
type = types.ints.positive;
|
|
default = 2;
|
|
description = "Limit the amount of concurrent indexers.";
|
|
};
|
|
|
|
databasePath = mkOption {
|
|
type = types.path;
|
|
default = "${config.xdg.dataHome}/hound";
|
|
defaultText = "$XDG_DATA_HOME/hound";
|
|
description = "The Hound database path.";
|
|
};
|
|
|
|
listenAddress = mkOption {
|
|
type = types.str;
|
|
default = "localhost:6080";
|
|
description = "Listen address of the Hound daemon.";
|
|
};
|
|
|
|
repositories = mkOption {
|
|
type = types.attrsOf jsonFormat.type;
|
|
default = { };
|
|
example = literalExample ''
|
|
{
|
|
SomeGitRepo = {
|
|
url = "https://www.github.com/YourOrganization/RepoOne.git";
|
|
ms-between-poll = 10000;
|
|
exclude-dot-files = true;
|
|
};
|
|
}
|
|
'';
|
|
description = "The repository configuration.";
|
|
};
|
|
};
|
|
|
|
config = mkIf cfg.enable {
|
|
assertions = [
|
|
(lib.hm.assertions.assertPlatform "services.hound" pkgs
|
|
lib.platforms.linux)
|
|
];
|
|
|
|
home.packages = [ pkgs.hound ];
|
|
|
|
systemd.user.services.hound = {
|
|
Unit = { Description = "Hound source code search engine"; };
|
|
|
|
Install = { WantedBy = [ "default.target" ]; };
|
|
|
|
Service = {
|
|
Environment = "PATH=${makeBinPath [ pkgs.mercurial pkgs.git ]}";
|
|
ExecStart =
|
|
"${pkgs.hound}/bin/houndd ${concatStringsSep " " houndOptions}";
|
|
};
|
|
};
|
|
};
|
|
}
|