mirror of
https://github.com/nix-community/home-manager
synced 2024-09-12 06:16:33 +02:00
These (and the `*MD` functions apart from `literalMD`) are now no-ops in nixpkgs and serve no purpose other than to add additional noise and potentially mislead people into thinking unmarked DocBook documentation will still be accepted. Note that if backporting changes including documentation to 23.05, the `mdDoc` calls will need to be re-added. To reproduce this commit, run: $ NIX_PATH=nixpkgs=flake:nixpkgs/e7e69199f0372364a6106a1e735f68604f4c5a25 \ nix shell nixpkgs#coreutils \ -c find . -name '*.nix' \ -exec nix run -- github:emilazy/nix-doc-munge/98dadf1f77351c2ba5dcb709a2a171d655f15099 \ --strip {} + $ ./format
67 lines
1.8 KiB
Nix
67 lines
1.8 KiB
Nix
{ config, lib, pkgs, ... }:
|
|
|
|
let
|
|
|
|
cfg = config.services.home-manager.autoUpgrade;
|
|
|
|
homeManagerPackage = pkgs.callPackage ../../home-manager {
|
|
path = config.programs.home-manager.path;
|
|
};
|
|
|
|
in {
|
|
meta.maintainers = [ lib.hm.maintainers.pinage404 ];
|
|
|
|
options = {
|
|
services.home-manager.autoUpgrade = {
|
|
enable = lib.mkEnableOption ''
|
|
the Home Manager upgrade service that periodically updates your Nix
|
|
channels before running `home-manager switch`'';
|
|
|
|
frequency = lib.mkOption {
|
|
type = lib.types.str;
|
|
example = "weekly";
|
|
description = ''
|
|
The interval at which the Home Manager auto upgrade is run.
|
|
This value is passed to the systemd timer configuration
|
|
as the `OnCalendar` option.
|
|
The format is described in
|
|
{manpage}`systemd.time(7)`.
|
|
'';
|
|
};
|
|
};
|
|
};
|
|
|
|
config = lib.mkIf cfg.enable {
|
|
assertions = [
|
|
(lib.hm.assertions.assertPlatform "services.home-manager.autoUpgrade" pkgs
|
|
lib.platforms.linux)
|
|
];
|
|
|
|
systemd.user = {
|
|
timers.home-manager-auto-upgrade = {
|
|
Unit.Description = "Home Manager upgrade timer";
|
|
|
|
Install.WantedBy = [ "timers.target" ];
|
|
|
|
Timer = {
|
|
OnCalendar = cfg.frequency;
|
|
Unit = "home-manager-auto-upgrade.service";
|
|
Persistent = true;
|
|
};
|
|
};
|
|
|
|
services.home-manager-auto-upgrade = {
|
|
Unit.Description = "Home Manager upgrade";
|
|
|
|
Service.ExecStart = toString
|
|
(pkgs.writeShellScript "home-manager-auto-upgrade" ''
|
|
echo "Update Nix's channels"
|
|
${pkgs.nix}/bin/nix-channel --update
|
|
echo "Upgrade Home Manager"
|
|
${homeManagerPackage}/bin/home-manager switch
|
|
'');
|
|
};
|
|
};
|
|
};
|
|
}
|