mirror of
https://github.com/nix-community/home-manager
synced 2024-09-12 06:16:33 +02:00
These (and the `*MD` functions apart from `literalMD`) are now no-ops in nixpkgs and serve no purpose other than to add additional noise and potentially mislead people into thinking unmarked DocBook documentation will still be accepted. Note that if backporting changes including documentation to 23.05, the `mdDoc` calls will need to be re-added. To reproduce this commit, run: $ NIX_PATH=nixpkgs=flake:nixpkgs/e7e69199f0372364a6106a1e735f68604f4c5a25 \ nix shell nixpkgs#coreutils \ -c find . -name '*.nix' \ -exec nix run -- github:emilazy/nix-doc-munge/98dadf1f77351c2ba5dcb709a2a171d655f15099 \ --strip {} + $ ./format
71 lines
1.7 KiB
Nix
71 lines
1.7 KiB
Nix
{ config, lib, pkgs, ... }:
|
|
|
|
let
|
|
cfg = config.services.comodoro;
|
|
|
|
args = with cfg; {
|
|
inherit preset;
|
|
protocols = if lib.isList protocols then
|
|
lib.concatStringsSep " " protocols
|
|
else
|
|
protocols;
|
|
};
|
|
|
|
in {
|
|
meta.maintainers = with lib.hm.maintainers; [ soywod ];
|
|
|
|
options.services.comodoro = {
|
|
enable = lib.mkEnableOption "Comodoro server";
|
|
|
|
package = lib.mkPackageOption pkgs "comodoro" { };
|
|
|
|
environment = lib.mkOption {
|
|
type = with lib.types; attrsOf str;
|
|
default = { };
|
|
example = lib.literalExpression ''
|
|
{
|
|
"PASSWORD_STORE_DIR" = "~/.password-store";
|
|
}
|
|
'';
|
|
description = ''
|
|
Extra environment variables to be exported in the service.
|
|
'';
|
|
};
|
|
|
|
preset = lib.mkOption {
|
|
type = lib.types.nonEmptyStr;
|
|
description = ''
|
|
Use configuration from the given preset as defined in the configuration file.
|
|
'';
|
|
};
|
|
|
|
protocols = lib.mkOption {
|
|
type = with lib.types; nonEmptyListOf nonEmptyStr;
|
|
description = ''
|
|
Define protocols the server should use to accept requests.
|
|
'';
|
|
};
|
|
};
|
|
|
|
config = lib.mkIf cfg.enable {
|
|
home.packages = [ cfg.package ];
|
|
|
|
systemd.user.services.comodoro = {
|
|
Unit = {
|
|
Description = "Comodoro server";
|
|
After = [ "network.target" ];
|
|
};
|
|
Install = { WantedBy = [ "default.target" ]; };
|
|
Service = {
|
|
ExecStart = with args;
|
|
"${cfg.package}/bin/comodoro server start ${preset} ${protocols}";
|
|
ExecSearchPath = "/bin";
|
|
Restart = "always";
|
|
RestartSec = 10;
|
|
Environment =
|
|
lib.mapAttrsToList (key: val: "${key}=${val}") cfg.environment;
|
|
};
|
|
};
|
|
};
|
|
}
|