mirror of
https://github.com/nix-community/home-manager
synced 2024-09-12 06:16:33 +02:00
These (and the `*MD` functions apart from `literalMD`) are now no-ops in nixpkgs and serve no purpose other than to add additional noise and potentially mislead people into thinking unmarked DocBook documentation will still be accepted. Note that if backporting changes including documentation to 23.05, the `mdDoc` calls will need to be re-added. To reproduce this commit, run: $ NIX_PATH=nixpkgs=flake:nixpkgs/e7e69199f0372364a6106a1e735f68604f4c5a25 \ nix shell nixpkgs#coreutils \ -c find . -name '*.nix' \ -exec nix run -- github:emilazy/nix-doc-munge/98dadf1f77351c2ba5dcb709a2a171d655f15099 \ --strip {} + $ ./format
93 lines
2.4 KiB
Nix
93 lines
2.4 KiB
Nix
{ config, lib, pkgs, ... }:
|
|
|
|
with lib;
|
|
|
|
let
|
|
|
|
cfg = config.programs.papis;
|
|
|
|
defaultLibraries = remove null
|
|
(mapAttrsToList (n: v: if v.isDefault then n else null) cfg.libraries);
|
|
|
|
settingsIni = (lib.mapAttrs (n: v: v.settings) cfg.libraries) // {
|
|
settings = cfg.settings // { "default-library" = head defaultLibraries; };
|
|
};
|
|
|
|
in {
|
|
meta.maintainers = [ ];
|
|
|
|
options.programs.papis = {
|
|
enable = mkEnableOption "papis";
|
|
|
|
settings = mkOption {
|
|
type = with types; attrsOf (oneOf [ bool int str ]);
|
|
default = { };
|
|
example = literalExpression ''
|
|
{
|
|
editor = "nvim";
|
|
file-browser = "ranger"
|
|
add-edit = true;
|
|
}
|
|
'';
|
|
description = ''
|
|
Configuration written to
|
|
{file}`$XDG_CONFIG_HOME/papis/config`. See
|
|
<https://papis.readthedocs.io/en/latest/configuration.html>
|
|
for supported values.
|
|
'';
|
|
};
|
|
|
|
libraries = mkOption {
|
|
type = types.attrsOf (types.submodule ({ config, name, ... }: {
|
|
options = {
|
|
name = mkOption {
|
|
type = types.str;
|
|
default = name;
|
|
readOnly = true;
|
|
description = "This library's name.";
|
|
};
|
|
|
|
isDefault = mkOption {
|
|
type = types.bool;
|
|
default = false;
|
|
example = true;
|
|
description = ''
|
|
Whether this is a default library. There must be exactly one
|
|
default library.
|
|
'';
|
|
};
|
|
|
|
settings = mkOption {
|
|
type = with types; attrsOf (oneOf [ bool int str ]);
|
|
default = { };
|
|
example = literalExpression ''
|
|
{
|
|
dir = "~/papers/";
|
|
}
|
|
'';
|
|
description = ''
|
|
Configuration for this library.
|
|
'';
|
|
};
|
|
};
|
|
}));
|
|
description = "Attribute set of papis libraries.";
|
|
};
|
|
};
|
|
|
|
config = mkIf cfg.enable {
|
|
assertions = [{
|
|
assertion = cfg.libraries == { } || length defaultLibraries == 1;
|
|
message = "Must have exactly one default papis library, but found "
|
|
+ toString (length defaultLibraries)
|
|
+ optionalString (length defaultLibraries > 1)
|
|
(", namely " + concatStringsSep "," defaultLibraries);
|
|
}];
|
|
|
|
home.packages = [ pkgs.papis ];
|
|
|
|
xdg.configFile."papis/config" =
|
|
mkIf (cfg.libraries != { }) { text = generators.toINI { } settingsIni; };
|
|
};
|
|
}
|