mirror of
https://github.com/nix-community/home-manager
synced 2024-09-12 06:16:33 +02:00
These (and the `*MD` functions apart from `literalMD`) are now no-ops in nixpkgs and serve no purpose other than to add additional noise and potentially mislead people into thinking unmarked DocBook documentation will still be accepted. Note that if backporting changes including documentation to 23.05, the `mdDoc` calls will need to be re-added. To reproduce this commit, run: $ NIX_PATH=nixpkgs=flake:nixpkgs/e7e69199f0372364a6106a1e735f68604f4c5a25 \ nix shell nixpkgs#coreutils \ -c find . -name '*.nix' \ -exec nix run -- github:emilazy/nix-doc-munge/98dadf1f77351c2ba5dcb709a2a171d655f15099 \ --strip {} + $ ./format
65 lines
1.4 KiB
Nix
65 lines
1.4 KiB
Nix
{ config, lib, pkgs, ... }:
|
|
|
|
with lib;
|
|
|
|
let
|
|
|
|
cfg = config.programs.btop;
|
|
|
|
finalConfig = let
|
|
toKeyValue = generators.toKeyValue {
|
|
mkKeyValue = generators.mkKeyValueDefault {
|
|
mkValueString = v:
|
|
with builtins;
|
|
if isBool v then
|
|
(if v then "True" else "False")
|
|
else if isString v then
|
|
''"${v}"''
|
|
else
|
|
toString v;
|
|
} " = ";
|
|
};
|
|
in ''
|
|
${toKeyValue cfg.settings}
|
|
${optionalString (cfg.extraConfig != "") cfg.extraConfig}
|
|
'';
|
|
|
|
in {
|
|
meta.maintainers = [ hm.maintainers.GaetanLepage ];
|
|
|
|
options.programs.btop = {
|
|
enable = mkEnableOption "btop";
|
|
|
|
package = mkPackageOption pkgs "btop" { };
|
|
|
|
settings = mkOption {
|
|
type = with types; attrsOf (oneOf [ bool float int str ]);
|
|
default = { };
|
|
example = {
|
|
color_theme = "Default";
|
|
theme_background = false;
|
|
};
|
|
description = ''
|
|
Options to add to {file}`btop.conf` file.
|
|
See <https://github.com/aristocratos/btop#configurability>
|
|
for options.
|
|
'';
|
|
};
|
|
|
|
extraConfig = mkOption {
|
|
type = types.lines;
|
|
default = "";
|
|
description = ''
|
|
Extra lines added to the {file}`btop.conf` file.
|
|
'';
|
|
};
|
|
};
|
|
|
|
config = mkIf cfg.enable {
|
|
home.packages = [ cfg.package ];
|
|
|
|
xdg.configFile."btop/btop.conf" =
|
|
mkIf (cfg.settings != { }) { text = finalConfig; };
|
|
};
|
|
}
|