mirror of
https://github.com/nix-community/home-manager
synced 2024-06-02 13:03:33 +02:00
5f433eb164
Before, loading a module would be guarded by an optional platform condition. This made it possible to avoid loading and evaluating a module if it did not support the host platform. Unfortunately, this made it impossible to share a single configuration between GNU/Linux and Darwin hosts, which some wish to do. This removes the conditional load and instead inserts host platform assertions in the modules that are platform specific. Fixes #1906
107 lines
2.6 KiB
Nix
107 lines
2.6 KiB
Nix
{ config, lib, pkgs, ... }:
|
|
|
|
with lib;
|
|
|
|
let
|
|
|
|
cfg = config.services.mpdris2;
|
|
|
|
toIni = generators.toINI {
|
|
mkKeyValue = key: value:
|
|
let
|
|
value' = if isBool value then
|
|
(if value then "True" else "False")
|
|
else
|
|
toString value;
|
|
in "${key} = ${value'}";
|
|
};
|
|
|
|
mpdris2Conf = {
|
|
Connection = {
|
|
host = cfg.mpd.host;
|
|
port = cfg.mpd.port;
|
|
music_dir = cfg.mpd.musicDirectory;
|
|
};
|
|
|
|
Bling = {
|
|
notify = cfg.notifications;
|
|
mmkeys = cfg.multimediaKeys;
|
|
};
|
|
};
|
|
|
|
in {
|
|
meta.maintainers = [ maintainers.pjones ];
|
|
|
|
options.services.mpdris2 = {
|
|
enable = mkEnableOption "mpDris2 the MPD to MPRIS2 bridge";
|
|
notifications = mkEnableOption "song change notifications";
|
|
multimediaKeys = mkEnableOption "multimedia key support";
|
|
|
|
package = mkOption {
|
|
type = types.package;
|
|
default = pkgs.mpdris2;
|
|
defaultText = literalExample "pkgs.mpdris2";
|
|
description = "The mpDris2 package to use.";
|
|
};
|
|
|
|
mpd = {
|
|
host = mkOption {
|
|
type = types.str;
|
|
default = config.services.mpd.network.listenAddress;
|
|
defaultText = "config.services.mpd.network.listenAddress";
|
|
example = "192.168.1.1";
|
|
description = "The address where MPD is listening for connections.";
|
|
};
|
|
|
|
port = mkOption {
|
|
type = types.port;
|
|
default = config.services.mpd.network.port;
|
|
defaultText = "config.services.mpd.network.port";
|
|
description = ''
|
|
The port number where MPD is listening for connections.
|
|
'';
|
|
};
|
|
|
|
musicDirectory = mkOption {
|
|
type = types.nullOr types.path;
|
|
default = config.services.mpd.musicDirectory;
|
|
defaultText = "config.services.mpd.musicDirectory";
|
|
description = ''
|
|
If set, mpDris2 will use this directory to access music artwork.
|
|
'';
|
|
};
|
|
};
|
|
};
|
|
|
|
config = mkIf cfg.enable {
|
|
assertions = [
|
|
(lib.hm.assertions.assertPlatform "services.mpdris2" pkgs
|
|
lib.platforms.linux)
|
|
|
|
{
|
|
assertion = config.services.mpd.enable;
|
|
message = "The mpdris2 module requires 'services.mpd.enable = true'.";
|
|
}
|
|
];
|
|
|
|
xdg.configFile."mpDris2/mpDris2.conf".text = toIni mpdris2Conf;
|
|
|
|
systemd.user.services.mpdris2 = {
|
|
Install = { WantedBy = [ "default.target" ]; };
|
|
|
|
Unit = {
|
|
Description = "MPRIS 2 support for MPD";
|
|
After = [ "mpd.service" ];
|
|
};
|
|
|
|
Service = {
|
|
Type = "simple";
|
|
Restart = "on-failure";
|
|
RestartSec = "5s";
|
|
ExecStart = "${cfg.package}/bin/mpDris2";
|
|
BusName = "org.mpris.MediaPlayer2.mpd";
|
|
};
|
|
};
|
|
};
|
|
}
|