mirror of
https://github.com/nix-community/home-manager
synced 2024-11-30 15:09:46 +01:00
51e1d69f7a
This fixes a regression introduced in
8d7e352a4b. That commit made the false
assumption that utils would have propagated from Nixpkgs to Home
Manager. This commit copies in `escapeSystemdExecArgs` to fix the
immediate issue, perhaps we can pull this in some other way later down
the line.
62 lines
1.6 KiB
Nix
62 lines
1.6 KiB
Nix
{ config, lib, pkgs, ... }:
|
|
|
|
with lib;
|
|
|
|
let
|
|
inherit (lib.strings) toJSON;
|
|
cfg = config.services.poweralertd;
|
|
escapeSystemdExecArg = arg:
|
|
let
|
|
s = if isPath arg then
|
|
"${arg}"
|
|
else if isString arg then
|
|
arg
|
|
else if isInt arg || isFloat arg || isDerivation arg then
|
|
toString arg
|
|
else
|
|
throw
|
|
"escapeSystemdExecArg only allows strings, paths, numbers and derivations";
|
|
in replaceStrings [ "%" "$" ] [ "%%" "$$" ] (toJSON s);
|
|
escapeSystemdExecArgs = concatMapStringsSep " " escapeSystemdExecArg;
|
|
in {
|
|
meta.maintainers = [ maintainers.thibautmarty ];
|
|
|
|
options.services.poweralertd = {
|
|
enable = mkEnableOption "the Upower-powered power alertd";
|
|
|
|
extraArgs = mkOption {
|
|
type = with types; listOf str;
|
|
default = [ ];
|
|
example = [ "-s" "-S" ];
|
|
description = ''
|
|
Extra command line arguments to pass to poweralertd.
|
|
'';
|
|
};
|
|
};
|
|
|
|
config = mkIf cfg.enable {
|
|
assertions = [
|
|
(lib.hm.assertions.assertPlatform "services.poweralertd" pkgs
|
|
lib.platforms.linux)
|
|
];
|
|
|
|
systemd.user.services.poweralertd = {
|
|
Unit = {
|
|
Description = "UPower-powered power alerter";
|
|
Documentation = "man:poweralertd(1)";
|
|
After = [ "graphical-session-pre.target" ];
|
|
PartOf = [ "graphical-session.target" ];
|
|
};
|
|
|
|
Install.WantedBy = [ "graphical-session.target" ];
|
|
|
|
Service = {
|
|
Type = "simple";
|
|
ExecStart = "${pkgs.poweralertd}/bin/poweralertd ${
|
|
escapeSystemdExecArgs cfg.extraArgs
|
|
}";
|
|
Restart = "always";
|
|
};
|
|
};
|
|
};
|
|
}
|