mirror of
https://github.com/nix-community/home-manager
synced 2024-07-06 21:33:28 +02:00
c1d8d2a3d1
The NixOS variant of Markdown doesn't make a distinction between `<code>` and `<literal>` or `<quote>` and... quotes, and doesn't support `<parameter>` or `<replaceable>`. These are infrequently used (apart from `<code>`) and don't add much, so just convert them to simpler forms to allow the options containing them to be converted to Markdown automatically. A few minor syntactic adjustments were also made to make `nix-doc-munge`'s job easier.
46 lines
1.4 KiB
Nix
46 lines
1.4 KiB
Nix
{ config, lib, pkgs, ... }:
|
|
|
|
with lib;
|
|
|
|
let
|
|
cfg = config.targets.darwin;
|
|
homeDir = config.home.homeDirectory;
|
|
confFile = pkgs.writeText "DefaultKeybinding.dict"
|
|
(lib.generators.toPlist { } cfg.keybindings);
|
|
in {
|
|
options.targets.darwin.keybindings = mkOption {
|
|
type = with types; attrsOf anything;
|
|
default = { };
|
|
example = {
|
|
"^u" = "deleteToBeginningOfLine:";
|
|
"^w" = "deleteWordBackward:";
|
|
};
|
|
description = ''
|
|
This will configure the default keybindings for text fields in macOS
|
|
applications. See
|
|
<link xlink:href="https://developer.apple.com/library/archive/documentation/Cocoa/Conceptual/EventOverview/TextDefaultsBindings/TextDefaultsBindings.html">Apple's documentation</link>
|
|
for more details.
|
|
|
|
<warning>
|
|
<para>Existing keybinding configuration will be wiped when using this
|
|
option.</para>
|
|
</warning>
|
|
'';
|
|
};
|
|
|
|
config = mkIf (cfg.keybindings != { }) {
|
|
assertions = [
|
|
(hm.assertions.assertPlatform "targets.darwin.keybindings" pkgs
|
|
platforms.darwin)
|
|
];
|
|
|
|
# NOTE: just copy the files because symlinks won't be recognized by macOS
|
|
home.activation.setCocoaKeybindings =
|
|
hm.dag.entryAfter [ "writeBoundary" ] ''
|
|
$VERBOSE_ECHO "Configuring keybindings for the Cocoa Text System"
|
|
$DRY_RUN_CMD install -Dm644 $VERBOSE_ARG \
|
|
"${confFile}" "${homeDir}/Library/KeyBindings/DefaultKeyBinding.dict"
|
|
'';
|
|
};
|
|
}
|