mirror of
https://github.com/nix-community/home-manager
synced 2024-11-24 03:59:46 +01:00
9f9e277b60
These (and the `*MD` functions apart from `literalMD`) are now no-ops
in nixpkgs and serve no purpose other than to add additional noise and
potentially mislead people into thinking unmarked DocBook documentation
will still be accepted.
Note that if backporting changes including documentation to 23.05,
the `mdDoc` calls will need to be re-added.
To reproduce this commit, run:
$ NIX_PATH=nixpkgs=flake:nixpkgs/e7e69199f0372364a6106a1e735f68604f4c5a25 \
nix shell nixpkgs#coreutils \
-c find . -name '*.nix' \
-exec nix run -- github:emilazy/nix-doc-munge/98dadf1f77351c2ba5dcb709a2a171d655f15099 \
--strip {} +
$ ./format
94 lines
2.5 KiB
Nix
94 lines
2.5 KiB
Nix
{ config, lib, pkgs, ... }:
|
|
|
|
with lib;
|
|
|
|
let
|
|
|
|
cfg = config.programs.watson;
|
|
|
|
iniFormat = pkgs.formats.ini { };
|
|
|
|
configDir = if pkgs.stdenv.hostPlatform.isDarwin then
|
|
"Library/Application Support"
|
|
else
|
|
config.xdg.configHome;
|
|
|
|
in {
|
|
meta.maintainers = [ maintainers.polykernel ];
|
|
|
|
options.programs.watson = {
|
|
enable = mkEnableOption "watson, a wonderful CLI to track your time";
|
|
|
|
package = mkOption {
|
|
type = types.package;
|
|
default = pkgs.watson;
|
|
defaultText = literalExpression "pkgs.watson";
|
|
description = "Package providing the {command}`watson`.";
|
|
};
|
|
|
|
enableBashIntegration = mkEnableOption "watson's bash integration" // {
|
|
default = true;
|
|
};
|
|
|
|
enableZshIntegration = mkEnableOption "watson's zsh integration" // {
|
|
default = true;
|
|
};
|
|
|
|
enableFishIntegration = mkEnableOption "watson's fish integration" // {
|
|
default = true;
|
|
};
|
|
|
|
settings = mkOption {
|
|
type = iniFormat.type;
|
|
default = { };
|
|
description = ''
|
|
Configuration written to
|
|
{file}`$XDG_CONFIG_HOME/watson/config` on Linux or
|
|
{file}`$HOME/Library/Application Support/watson/config` on Darwin.
|
|
|
|
See <https://github.com/TailorDev/Watson/blob/master/docs/user-guide/configuration.md>
|
|
for an example configuration.
|
|
'';
|
|
example = literalExpression ''
|
|
{
|
|
backend = {
|
|
url = "https://api.crick.fr";
|
|
token = "yourapitoken";
|
|
};
|
|
|
|
options = {
|
|
stop_on_start = true;
|
|
stop_on_restart = false;
|
|
date_format = "%Y.%m.%d";
|
|
time_format = "%H:%M:%S%z";
|
|
week_start = "monday";
|
|
log_current = false;
|
|
pager = true;
|
|
report_current = false;
|
|
reverse_log = true;
|
|
};
|
|
}
|
|
'';
|
|
};
|
|
};
|
|
|
|
config = mkIf cfg.enable {
|
|
home.packages = [ cfg.package ];
|
|
|
|
home.file."${configDir}/watson/config" = mkIf (cfg.settings != { }) {
|
|
source = iniFormat.generate "watson-config" cfg.settings;
|
|
};
|
|
|
|
programs.bash.initExtra = mkIf cfg.enableBashIntegration ''
|
|
source ${cfg.package}/share/bash-completion/completions/watson
|
|
'';
|
|
|
|
programs.zsh.initExtra = mkIf cfg.enableZshIntegration ''
|
|
source ${cfg.package}/share/zsh/site-functions/_watson
|
|
'';
|
|
|
|
programs.fish.shellInit = mkIf cfg.enableFishIntegration ''
|
|
source ${cfg.package}/share/fish/vendor_completions.d/watson.fish
|
|
'';
|
|
};
|
|
}
|