mirror of
https://github.com/nix-community/home-manager
synced 2024-06-02 13:03:33 +02:00
c7592b747b
Currently, dot directories and XDG base directories are used inconsistently in the Home Manager option declarations. This creates ambiguity for the user as to where the location of the file should be albeit this is rarely encountered in practice as it is sufficient to read upstream documentation. The rationale is to make declarations consistent and make a clear distinction between hardcoded and modular specifications. References to ~/.config in relevant nixpkgs modules were untouched as the location is hardcoded upstream[1]. Furthermore, modules of programs which do not follow XDG specifications were also untouched. Generalization of tilde(~) expansions to $HOME were also considered, however there isn't sufficient rationale despite the use of $HOME being more universal. The expansion is standardized in POSIX[2] and is essentially portable across all shells, thus there is no pragmatic value to introducing the change. [1] https://github.com/nixos/nixpkgs/blob/master/pkgs/top-level/impure.nix [2] https://pubs.opengroup.org/onlinepubs/009695399/utilities/xcu_chap02.html#tag_02_06_01
61 lines
1.4 KiB
Nix
61 lines
1.4 KiB
Nix
{ config, lib, pkgs, ... }:
|
|
|
|
with lib;
|
|
|
|
let
|
|
|
|
cfg = config.programs.topgrade;
|
|
|
|
tomlFormat = pkgs.formats.toml { };
|
|
|
|
in {
|
|
|
|
meta.maintainers = [ hm.maintainers.msfjarvis ];
|
|
|
|
options.programs.topgrade = {
|
|
enable = mkEnableOption "topgrade";
|
|
|
|
package = mkOption {
|
|
type = types.package;
|
|
default = pkgs.topgrade;
|
|
defaultText = literalExpression "pkgs.topgrade";
|
|
description = "The package to use for the topgrade binary.";
|
|
};
|
|
|
|
settings = mkOption {
|
|
type = tomlFormat.type;
|
|
default = { };
|
|
defaultText = literalExpression "{ }";
|
|
example = literalExpression ''
|
|
{
|
|
assume_yes = true;
|
|
disable = [
|
|
"flutter"
|
|
"node"
|
|
];
|
|
set_title = false;
|
|
cleanup = true;
|
|
commands = {
|
|
"Run garbage collection on Nix store" = "nix-collect-garbage";
|
|
};
|
|
}
|
|
'';
|
|
description = ''
|
|
Configuration written to
|
|
<filename>$XDG_CONFIG_HOME/topgrade.toml</filename>.
|
|
</para><para>
|
|
See <link xlink:href="https://github.com/r-darwish/topgrade/wiki/Step-list" /> for the full list
|
|
of options.
|
|
'';
|
|
};
|
|
};
|
|
|
|
config = mkIf cfg.enable {
|
|
home.packages = [ cfg.package ];
|
|
|
|
xdg.configFile."topgrade.toml" = mkIf (cfg.settings != { }) {
|
|
source = tomlFormat.generate "topgrade-config" cfg.settings;
|
|
};
|
|
};
|
|
}
|