mirror of
https://github.com/nix-community/home-manager
synced 2024-11-24 03:59:46 +01:00
9f9e277b60
These (and the `*MD` functions apart from `literalMD`) are now no-ops
in nixpkgs and serve no purpose other than to add additional noise and
potentially mislead people into thinking unmarked DocBook documentation
will still be accepted.
Note that if backporting changes including documentation to 23.05,
the `mdDoc` calls will need to be re-added.
To reproduce this commit, run:
$ NIX_PATH=nixpkgs=flake:nixpkgs/e7e69199f0372364a6106a1e735f68604f4c5a25 \
nix shell nixpkgs#coreutils \
-c find . -name '*.nix' \
-exec nix run -- github:emilazy/nix-doc-munge/98dadf1f77351c2ba5dcb709a2a171d655f15099 \
--strip {} +
$ ./format
67 lines
1.7 KiB
Nix
67 lines
1.7 KiB
Nix
{ config, lib, pkgs, ... }:
|
|
|
|
with lib;
|
|
|
|
let
|
|
cfg = config.wayland.windowManager.sway.swaynag;
|
|
|
|
iniFormat = pkgs.formats.ini { };
|
|
|
|
confFormat = with types;
|
|
let
|
|
confAtom = nullOr (oneOf [ bool int float str ]) // {
|
|
description = "Swaynag config atom (null, bool, int, float, str)";
|
|
};
|
|
in attrsOf confAtom;
|
|
in {
|
|
meta.maintainers = with maintainers; [ polykernel ];
|
|
|
|
options = {
|
|
wayland.windowManager.sway.swaynag = {
|
|
enable = mkEnableOption
|
|
"configuration of swaynag, a lightweight error bar for sway";
|
|
|
|
settings = mkOption {
|
|
type = types.attrsOf confFormat;
|
|
default = { };
|
|
description = ''
|
|
Configuration written to
|
|
{file}`$XDG_CONFIG_HOME/swaynag/config`.
|
|
|
|
See
|
|
{manpage}`swaynag(5)`
|
|
for a list of available options and an example configuration.
|
|
Note, configurations declared under `<config>`
|
|
will override the default type values of swaynag.
|
|
'';
|
|
example = literalExpression ''
|
|
{
|
|
"<config>" = {
|
|
edge = "bottom";
|
|
font = "Dina 12";
|
|
};
|
|
|
|
green = {
|
|
edge = "top";
|
|
background = "00AA00";
|
|
text = "FFFFFF";
|
|
button-background = "00CC00";
|
|
message-padding = 10;
|
|
};
|
|
}
|
|
'';
|
|
};
|
|
};
|
|
};
|
|
|
|
config = mkIf cfg.enable {
|
|
assertions = [
|
|
(hm.assertions.assertPlatform "wayland.windowManager.sway.swaynag" pkgs
|
|
platforms.linux)
|
|
];
|
|
|
|
xdg.configFile."swaynag/config" = mkIf (cfg.settings != { }) {
|
|
source = iniFormat.generate "swaynag.conf" cfg.settings;
|
|
};
|
|
};
|
|
}
|