mirror of
https://github.com/nix-community/home-manager
synced 2024-11-05 02:39:45 +01:00
cc58d31953
* flake: Expose tests to allow running purely The existing way to run tests with `nix-shell` relies on impure usage of `<nixpkgs>`. This can lead to failures when the local nixpkgs is incompatible with the locked one. I.e., where CI is passing but a contributor may experience a failure. So, expose tests as `devShells.tests` to use the locked nixpkgs and allow easy invocation via `nix develop`. * tests: Remove impure path With Nix 2.10+ and pure evaluation mode e.g. ``` nix run nixpkgs/nixos-unstable#nixVersions.nix_2_10 -- develop -i .#tests.zplug-modules ``` this test would fail with: > error: the path '~/.customZplugHome' can not be resolved in pure mode Since the test only cares that it is a path, rather than anything about its contents, use a dummy empty directory.
104 lines
3.2 KiB
Nix
104 lines
3.2 KiB
Nix
{
|
|
description = "Home Manager for Nix";
|
|
|
|
inputs.nixpkgs.url = "github:nixos/nixpkgs/nixos-unstable";
|
|
inputs.utils.url = "github:numtide/flake-utils";
|
|
|
|
outputs = { self, nixpkgs, utils, ... }:
|
|
{
|
|
nixosModules = rec {
|
|
home-manager = import ./nixos;
|
|
default = home-manager;
|
|
};
|
|
# deprecated in Nix 2.8
|
|
nixosModule = self.nixosModules.default;
|
|
|
|
darwinModules = rec {
|
|
home-manager = import ./nix-darwin;
|
|
default = home-manager;
|
|
};
|
|
# unofficial; deprecated in Nix 2.8
|
|
darwinModule = self.darwinModules.default;
|
|
|
|
templates = {
|
|
standalone = {
|
|
path = ./templates/standalone;
|
|
description = "Standalone setup";
|
|
};
|
|
nixos = {
|
|
path = ./templates/nixos;
|
|
description = "Home Manager as a NixOS module,";
|
|
};
|
|
nix-darwin = {
|
|
path = ./templates/nix-darwin;
|
|
description = "Home Manager as a nix-darwin module,";
|
|
};
|
|
};
|
|
|
|
defaultTemplate = self.templates.standalone;
|
|
|
|
lib = {
|
|
hm = (import ./modules/lib/stdlib-extended.nix nixpkgs.lib).hm;
|
|
homeManagerConfiguration = { modules ? [ ], pkgs, lib ? pkgs.lib
|
|
, extraSpecialArgs ? { }, check ? true
|
|
# Deprecated:
|
|
, configuration ? null, extraModules ? null, stateVersion ? null
|
|
, username ? null, homeDirectory ? null, system ? null }@args:
|
|
let
|
|
msgForRemovedArg = ''
|
|
The 'homeManagerConfiguration' arguments
|
|
|
|
- 'configuration',
|
|
- 'username',
|
|
- 'homeDirectory'
|
|
- 'stateVersion',
|
|
- 'extraModules', and
|
|
- 'system'
|
|
|
|
have been removed. Instead use the arguments 'pkgs' and
|
|
'modules'. See the 22.11 release notes for more.
|
|
'';
|
|
|
|
throwForRemovedArgs = v:
|
|
let
|
|
used = builtins.filter (n: (args.${n} or null) != null) [
|
|
"configuration"
|
|
"username"
|
|
"homeDirectory"
|
|
"stateVersion"
|
|
"extraModules"
|
|
"system"
|
|
];
|
|
msg = msgForRemovedArg + ''
|
|
|
|
|
|
Deprecated args passed: ''
|
|
+ builtins.concatStringsSep " " used;
|
|
in lib.throwIf (used != [ ]) msg v;
|
|
|
|
in throwForRemovedArgs (import ./modules {
|
|
inherit pkgs lib check extraSpecialArgs;
|
|
configuration = { ... }: {
|
|
imports = modules;
|
|
nixpkgs = { inherit (pkgs) config overlays; };
|
|
};
|
|
});
|
|
};
|
|
} // utils.lib.eachDefaultSystem (system:
|
|
let
|
|
pkgs = nixpkgs.legacyPackages.${system};
|
|
docs = import ./docs { inherit pkgs; };
|
|
tests = import ./tests { inherit pkgs; };
|
|
in {
|
|
devShells.tests = tests.run;
|
|
packages = rec {
|
|
home-manager = pkgs.callPackage ./home-manager { };
|
|
docs-html = docs.manual.html;
|
|
docs-manpages = docs.manPages;
|
|
docs-json = docs.options.json;
|
|
default = home-manager;
|
|
};
|
|
# deprecated in Nix 2.7
|
|
defaultPackage = self.packages.${system}.default;
|
|
});
|
|
}
|