mirror of
https://github.com/nix-community/home-manager
synced 2024-12-05 01:19:46 +01:00
9f9e277b60
These (and the `*MD` functions apart from `literalMD`) are now no-ops
in nixpkgs and serve no purpose other than to add additional noise and
potentially mislead people into thinking unmarked DocBook documentation
will still be accepted.
Note that if backporting changes including documentation to 23.05,
the `mdDoc` calls will need to be re-added.
To reproduce this commit, run:
$ NIX_PATH=nixpkgs=flake:nixpkgs/e7e69199f0372364a6106a1e735f68604f4c5a25 \
nix shell nixpkgs#coreutils \
-c find . -name '*.nix' \
-exec nix run -- github:emilazy/nix-doc-munge/98dadf1f77351c2ba5dcb709a2a171d655f15099 \
--strip {} +
$ ./format
51 lines
1.2 KiB
Nix
51 lines
1.2 KiB
Nix
{ config, lib, pkgs, ... }:
|
|
|
|
let
|
|
|
|
inherit (lib) literalExpression mkEnableOption mkPackageOption mkOption mkIf;
|
|
|
|
cfg = config.programs.fuzzel;
|
|
|
|
iniFormat = pkgs.formats.ini { };
|
|
|
|
in {
|
|
meta.maintainers = [ lib.maintainers.Scrumplex ];
|
|
|
|
options.programs.fuzzel = {
|
|
enable = mkEnableOption "fuzzel";
|
|
|
|
package = mkPackageOption pkgs "fuzzel" { };
|
|
|
|
settings = mkOption {
|
|
type = iniFormat.type;
|
|
default = { };
|
|
example = literalExpression ''
|
|
{
|
|
main = {
|
|
terminal = "''${pkgs.foot}/bin/foot";
|
|
layer = "overlay";
|
|
};
|
|
colors.background = "ffffffff";
|
|
}
|
|
'';
|
|
description = ''
|
|
Configuration for fuzzel written to
|
|
{file}`$XDG_CONFIG_HOME/fuzzel/fuzzel.ini`. See
|
|
{manpage}`fuzzel.ini(5)` for a list of available options.
|
|
'';
|
|
};
|
|
};
|
|
|
|
config = mkIf cfg.enable {
|
|
assertions = [
|
|
(lib.hm.assertions.assertPlatform "programs.fuzzel" pkgs
|
|
lib.platforms.linux)
|
|
];
|
|
|
|
home.packages = [ cfg.package ];
|
|
|
|
xdg.configFile."fuzzel/fuzzel.ini" = mkIf (cfg.settings != { }) {
|
|
source = iniFormat.generate "fuzzel.ini" cfg.settings;
|
|
};
|
|
};
|
|
}
|