mirror of
https://github.com/nix-community/home-manager
synced 2024-11-05 02:39:45 +01:00
e0f2949c98
NixOS/nixpkgs@03310df843 disabled flake support by default, so we now need to build a custom package and use it if the user wants to `use flake` successfully. This should fix #2087.
114 lines
2.9 KiB
Nix
114 lines
2.9 KiB
Nix
{ config, lib, pkgs, ... }:
|
|
|
|
with lib;
|
|
|
|
let
|
|
|
|
cfg = config.programs.direnv;
|
|
|
|
tomlFormat = pkgs.formats.toml { };
|
|
|
|
in {
|
|
imports = [
|
|
(mkRenamedOptionModule [
|
|
"programs"
|
|
"direnv"
|
|
"enableNixDirenvIntegration"
|
|
] [ "programs" "direnv" "nix-direnv" "enable" ])
|
|
];
|
|
|
|
meta.maintainers = [ maintainers.rycee ];
|
|
|
|
options.programs.direnv = {
|
|
enable = mkEnableOption "direnv, the environment switcher";
|
|
|
|
config = mkOption {
|
|
type = tomlFormat.type;
|
|
default = { };
|
|
description = ''
|
|
Configuration written to
|
|
<filename>~/.config/direnv/config.toml</filename>.
|
|
</para><para>
|
|
See
|
|
<citerefentry>
|
|
<refentrytitle>direnv.toml</refentrytitle>
|
|
<manvolnum>1</manvolnum>
|
|
</citerefentry>.
|
|
for the full list of options.
|
|
'';
|
|
};
|
|
|
|
stdlib = mkOption {
|
|
type = types.lines;
|
|
default = "";
|
|
description = ''
|
|
Custom stdlib written to
|
|
<filename>~/.config/direnv/direnvrc</filename>.
|
|
'';
|
|
};
|
|
|
|
enableBashIntegration = mkOption {
|
|
default = true;
|
|
type = types.bool;
|
|
description = ''
|
|
Whether to enable Bash integration.
|
|
'';
|
|
};
|
|
|
|
enableZshIntegration = mkOption {
|
|
default = true;
|
|
type = types.bool;
|
|
description = ''
|
|
Whether to enable Zsh integration.
|
|
'';
|
|
};
|
|
|
|
enableFishIntegration = mkOption {
|
|
default = true;
|
|
type = types.bool;
|
|
description = ''
|
|
Whether to enable Fish integration.
|
|
'';
|
|
};
|
|
|
|
nix-direnv = {
|
|
enable = mkEnableOption ''
|
|
<link
|
|
xlink:href="https://github.com/nix-community/nix-direnv">nix-direnv</link>,
|
|
a fast, persistent use_nix implementation for direnv'';
|
|
enableFlakes = mkEnableOption "Flake support in nix-direnv";
|
|
};
|
|
|
|
};
|
|
|
|
config = mkIf cfg.enable {
|
|
home.packages = [ pkgs.direnv ];
|
|
|
|
xdg.configFile."direnv/config.toml" = mkIf (cfg.config != { }) {
|
|
source = tomlFormat.generate "direnv-config" cfg.config;
|
|
};
|
|
|
|
xdg.configFile."direnv/direnvrc" = let
|
|
package =
|
|
pkgs.nix-direnv.override { inherit (cfg.nix-direnv) enableFlakes; };
|
|
text = concatStringsSep "\n" (optional (cfg.stdlib != "") cfg.stdlib
|
|
++ optional cfg.nix-direnv.enable
|
|
"source ${package}/share/nix-direnv/direnvrc");
|
|
in mkIf (text != "") { inherit text; };
|
|
|
|
programs.bash.initExtra = mkIf cfg.enableBashIntegration (
|
|
# Using mkAfter to make it more likely to appear after other
|
|
# manipulations of the prompt.
|
|
mkAfter ''
|
|
eval "$(${pkgs.direnv}/bin/direnv hook bash)"
|
|
'');
|
|
|
|
programs.zsh.initExtra = mkIf cfg.enableZshIntegration ''
|
|
eval "$(${pkgs.direnv}/bin/direnv hook zsh)"
|
|
'';
|
|
|
|
programs.fish.shellInit = mkIf cfg.enableFishIntegration ''
|
|
${pkgs.direnv}/bin/direnv hook fish | source
|
|
'';
|
|
};
|
|
}
|