mirror of
https://github.com/nix-community/home-manager
synced 2024-06-27 17:08:31 +02:00
8991fe2e90
In particular, don't add trailing backslashes introduced by `xautolockExtraOptions`. Systemd's unit file parser seems to have gotten a bit stricter and with systemd 242, the trailing backslash caused the next non-empty line to be ignored. In that case, this was `[Section]`, so all subsequent settings were mistakenly added to `[Service]`, causing them to be ignored entirely. Simplify and fix this by using `concatStringsSep` to build a single `ExecStart` line.
77 lines
2.1 KiB
Nix
77 lines
2.1 KiB
Nix
{ config, lib, pkgs, ... }:
|
|
|
|
with lib;
|
|
|
|
let
|
|
|
|
cfg = config.services.screen-locker;
|
|
|
|
in {
|
|
|
|
options.services.screen-locker = {
|
|
enable = mkEnableOption "screen locker for X session";
|
|
|
|
lockCmd = mkOption {
|
|
type = types.str;
|
|
description = "Locker command to run.";
|
|
example = "\${pkgs.i3lock}/bin/i3lock -n -c 000000";
|
|
};
|
|
|
|
inactiveInterval = mkOption {
|
|
type = types.int;
|
|
default = 10;
|
|
description = ''
|
|
Inactive time interval in minutes after which session will be locked.
|
|
The minimum is 1 minute, and the maximum is 1 hour.
|
|
See <link xlink:href="https://linux.die.net/man/1/xautolock"/>.
|
|
'';
|
|
};
|
|
|
|
xautolockExtraOptions = mkOption {
|
|
type = types.listOf types.str;
|
|
default = [];
|
|
description = ''
|
|
Extra command-line arguments to pass to <command>xautolock</command>.
|
|
'';
|
|
};
|
|
|
|
xssLockExtraOptions = mkOption {
|
|
type = types.listOf types.str;
|
|
default = [];
|
|
description = ''
|
|
Extra command-line arguments to pass to <command>xss-lock</command>.
|
|
'';
|
|
};
|
|
|
|
};
|
|
|
|
config = mkIf cfg.enable {
|
|
systemd.user.services.xautolock-session = {
|
|
Unit = {
|
|
Description = "xautolock, session locker service";
|
|
After = [ "graphical-session-pre.target" ];
|
|
PartOf = [ "graphical-session.target" ];
|
|
};
|
|
|
|
Install = {
|
|
WantedBy = [ "graphical-session.target" ];
|
|
};
|
|
|
|
Service = {
|
|
ExecStart = concatStringsSep " " ([
|
|
"${pkgs.xautolock}/bin/xautolock"
|
|
"-detectsleep"
|
|
"-time ${toString cfg.inactiveInterval}"
|
|
"-locker '${pkgs.systemd}/bin/loginctl lock-session $XDG_SESSION_ID'"
|
|
] ++ cfg.xautolockExtraOptions);
|
|
};
|
|
};
|
|
|
|
# xss-lock will run specified screen locker when the session is locked via loginctl
|
|
# can't be started as a systemd service,
|
|
# see https://bitbucket.org/raymonad/xss-lock/issues/13/allow-operation-as-systemd-user-unit
|
|
xsession.initExtra = "${pkgs.xss-lock}/bin/xss-lock ${concatStringsSep " " cfg.xssLockExtraOptions} -- ${cfg.lockCmd} &";
|
|
};
|
|
|
|
}
|