mirror of
https://github.com/nix-community/home-manager
synced 2024-12-30 21:59:49 +01:00
9f9e277b60
These (and the `*MD` functions apart from `literalMD`) are now no-ops
in nixpkgs and serve no purpose other than to add additional noise and
potentially mislead people into thinking unmarked DocBook documentation
will still be accepted.
Note that if backporting changes including documentation to 23.05,
the `mdDoc` calls will need to be re-added.
To reproduce this commit, run:
$ NIX_PATH=nixpkgs=flake:nixpkgs/e7e69199f0372364a6106a1e735f68604f4c5a25 \
nix shell nixpkgs#coreutils \
-c find . -name '*.nix' \
-exec nix run -- github:emilazy/nix-doc-munge/98dadf1f77351c2ba5dcb709a2a171d655f15099 \
--strip {} +
$ ./format
69 lines
1.6 KiB
Nix
69 lines
1.6 KiB
Nix
{ config, lib, pkgs, ... }:
|
|
|
|
with lib;
|
|
|
|
let
|
|
|
|
cfg = config.programs.ledger;
|
|
|
|
cfgText = generators.toKeyValue {
|
|
mkKeyValue = key: value:
|
|
if isBool value then
|
|
optionalString value "--${key}"
|
|
else
|
|
"--${key} ${toString value}";
|
|
listsAsDuplicateKeys = true;
|
|
} cfg.settings;
|
|
|
|
in {
|
|
meta.maintainers = [ ];
|
|
|
|
options.programs.ledger = {
|
|
enable = mkEnableOption "ledger, a double-entry accounting system";
|
|
|
|
package = mkPackageOption pkgs "ledger" { };
|
|
|
|
settings = mkOption {
|
|
type = with types; attrsOf (oneOf [ bool int str (listOf str) ]);
|
|
default = { };
|
|
example = {
|
|
sort = "date";
|
|
date-format = "%Y-%m-%d";
|
|
strict = true;
|
|
file = [
|
|
"~/finances/journal.ledger"
|
|
"~/finances/assets.ledger"
|
|
"~/finances/income.ledger"
|
|
];
|
|
};
|
|
description = ''
|
|
Configuration written to {file}`$XDG_CONFIG_HOME/ledger/ledgerrc`.
|
|
See <https://www.ledger-cli.org/3.0/doc/ledger3.html#Detailed-Option-Description>
|
|
for explanation about possible values.
|
|
'';
|
|
};
|
|
|
|
extraConfig = mkOption {
|
|
type = types.lines;
|
|
default = "";
|
|
example = literalExpression ''
|
|
--sort date
|
|
--effective
|
|
--date-format %Y-%m-%d
|
|
'';
|
|
description = ''
|
|
Extra configuration to add to
|
|
{file}`$XDG_CONFIG_HOME/ledger/ledgerrc`.
|
|
'';
|
|
};
|
|
};
|
|
|
|
config = mkIf cfg.enable {
|
|
home.packages = [ cfg.package ];
|
|
|
|
xdg.configFile."ledger/ledgerrc" =
|
|
mkIf (cfg.settings != { } || cfg.extraConfig != "") {
|
|
text = cfgText + cfg.extraConfig;
|
|
};
|
|
};
|
|
}
|