mirror of
https://github.com/nix-community/home-manager
synced 2024-12-26 03:39:47 +01:00
472ca211ca
The apropos software is useful to get a list of manpages matching a
description or to get a list of all manpages. The latter feature is
used by Emacs to get manpage completion (`M-x man`).
To have apropos working, a database of all available manpages must be
built with mandb. This is what this commits does.
A similar change was done for NixOS:
edc6a76cc0
72 lines
2.3 KiB
Nix
72 lines
2.3 KiB
Nix
{ config, lib, pkgs, ... }:
|
|
|
|
with lib;
|
|
|
|
{
|
|
options = {
|
|
programs.man = {
|
|
enable = mkOption {
|
|
type = types.bool;
|
|
default = true;
|
|
description = ''
|
|
Whether to enable manual pages and the <command>man</command>
|
|
command. This also includes "man" outputs of all
|
|
<literal>home.packages</literal>.
|
|
'';
|
|
};
|
|
|
|
generateCaches = mkOption {
|
|
type = types.bool;
|
|
default = false;
|
|
description = ''
|
|
Whether to generate the manual page index caches using
|
|
<citerefentry>
|
|
<refentrytitle>mandb</refentrytitle>
|
|
<manvolnum>8</manvolnum>
|
|
</citerefentry>. This allows searching for a page or
|
|
keyword using utilities like <citerefentry>
|
|
<refentrytitle>apropos</refentrytitle>
|
|
<manvolnum>1</manvolnum>
|
|
</citerefentry>.
|
|
</para><para>
|
|
This feature is disabled by default because it slows down
|
|
building. If you don't mind waiting a few more seconds when
|
|
Home Manager builds a new generation, you may safely enable
|
|
this option.
|
|
'';
|
|
};
|
|
};
|
|
};
|
|
|
|
config = mkIf config.programs.man.enable {
|
|
home.packages = [ pkgs.man ];
|
|
home.extraOutputsToInstall = [ "man" ];
|
|
|
|
# This is mostly copy/pasted/adapted from NixOS' documentation.nix.
|
|
home.file = mkIf config.programs.man.generateCaches {
|
|
".manpath".text = let
|
|
# Generate a directory containing installed packages' manpages.
|
|
manualPages = pkgs.buildEnv {
|
|
name = "man-paths";
|
|
paths = config.home.packages;
|
|
pathsToLink = [ "/share/man" ];
|
|
extraOutputsToInstall = [ "man" ];
|
|
ignoreCollisions = true;
|
|
};
|
|
|
|
# Generate a database of all manpages in ${manualPages}.
|
|
manualCache = pkgs.runCommandLocal "man-cache" { } ''
|
|
# Generate a temporary man.conf so mandb knows where to
|
|
# write cache files.
|
|
echo "MANDB_MAP ${manualPages}/share/man $out" > man.conf
|
|
|
|
# Run mandb to generate cache files:
|
|
${pkgs.man-db}/bin/mandb -C man.conf --no-straycats --create \
|
|
${manualPages}/share/man
|
|
'';
|
|
in ''
|
|
MANDB_MAP ${config.home.profileDirectory}/share/man ${manualCache}
|
|
'';
|
|
};
|
|
};
|
|
}
|