mirror of
https://github.com/nix-community/home-manager
synced 2024-12-25 11:19:47 +01:00
5f433eb164
Before, loading a module would be guarded by an optional platform condition. This made it possible to avoid loading and evaluating a module if it did not support the host platform. Unfortunately, this made it impossible to share a single configuration between GNU/Linux and Darwin hosts, which some wish to do. This removes the conditional load and instead inserts host platform assertions in the modules that are platform specific. Fixes #1906
126 lines
3.1 KiB
Nix
126 lines
3.1 KiB
Nix
{ config, lib, pkgs, ... }:
|
|
|
|
with lib;
|
|
|
|
let
|
|
|
|
cfg = config.services.unison;
|
|
|
|
pairOf = t:
|
|
let list = types.addCheck (types.listOf t) (l: length l == 2);
|
|
in list // { description = list.description + " of length 2"; };
|
|
|
|
pairOptions = {
|
|
options = {
|
|
stateDirectory = mkOption {
|
|
type = types.path;
|
|
default = "${config.xdg.dataHome}/unison";
|
|
defaultText = "$XDG_DATA_HOME/unison";
|
|
description = ''
|
|
Unison state directory to use.
|
|
'';
|
|
};
|
|
|
|
commandOptions = mkOption rec {
|
|
type = with types; attrsOf str;
|
|
apply = mergeAttrs default;
|
|
default = {
|
|
repeat = "watch";
|
|
sshcmd = "${pkgs.openssh}/bin/ssh";
|
|
ui = "text";
|
|
auto = "true";
|
|
batch = "true";
|
|
log = "false"; # don't log to file, handled by systemd
|
|
};
|
|
description = ''
|
|
Additional command line options as a dictionary to pass to the
|
|
<literal>unison</literal> program.
|
|
</para><para>
|
|
See
|
|
<citerefentry>
|
|
<refentrytitle>unison</refentrytitle>
|
|
<manvolnum>1</manvolnum>
|
|
</citerefentry>
|
|
for a list of available options.
|
|
'';
|
|
};
|
|
|
|
roots = mkOption {
|
|
type = pairOf types.str;
|
|
example = literalExample ''
|
|
[
|
|
"/home/user/documents"
|
|
"ssh://remote/documents"
|
|
]
|
|
'';
|
|
description = ''
|
|
Pair of roots to synchronise.
|
|
'';
|
|
};
|
|
};
|
|
};
|
|
|
|
serialiseArg = key: val: escapeShellArg "-${key}=${escape [ "=" ] val}";
|
|
|
|
serialiseArgs = args: concatStringsSep " " (mapAttrsToList serialiseArg args);
|
|
|
|
makeDefs = gen:
|
|
mapAttrs'
|
|
(name: pairCfg: nameValuePair "unison-pair-${name}" (gen name pairCfg))
|
|
cfg.pairs;
|
|
|
|
in {
|
|
meta.maintainers = with maintainers; [ pacien ];
|
|
|
|
options.services.unison = {
|
|
enable = mkEnableOption "Unison synchronisation";
|
|
|
|
pairs = mkOption {
|
|
type = with types; attrsOf (submodule pairOptions);
|
|
default = { };
|
|
example = literalExample ''
|
|
{
|
|
roots = [
|
|
"/home/user/documents"
|
|
"ssh://remote/documents"
|
|
];
|
|
}
|
|
'';
|
|
description = ''
|
|
Unison root pairs to keep synchronised.
|
|
'';
|
|
};
|
|
};
|
|
|
|
config = mkIf cfg.enable {
|
|
assertions = [
|
|
(lib.hm.assertions.assertPlatform "services.unison" pkgs
|
|
lib.platforms.linux)
|
|
];
|
|
|
|
systemd.user.services = makeDefs (name: pairCfg: {
|
|
Unit = {
|
|
Description = "Unison pair sync (${name})";
|
|
# Retry forever, useful in case of network disruption.
|
|
StartLimitIntervalSec = 0;
|
|
};
|
|
|
|
Service = {
|
|
Restart = "always";
|
|
RestartSec = 60;
|
|
|
|
CPUSchedulingPolicy = "idle";
|
|
IOSchedulingClass = "idle";
|
|
|
|
Environment = [ "UNISON='${toString pairCfg.stateDirectory}'" ];
|
|
ExecStart = ''
|
|
${pkgs.unison}/bin/unison \
|
|
${serialiseArgs pairCfg.commandOptions} \
|
|
${strings.concatMapStringsSep " " escapeShellArg pairCfg.roots}
|
|
'';
|
|
};
|
|
|
|
Install = { WantedBy = [ "default.target" ]; };
|
|
});
|
|
};
|
|
}
|