mirror of
https://github.com/nix-community/home-manager
synced 2024-07-02 11:28:32 +02:00
36a53d9f26
This process was automated by [my fork of `nix-doc-munge`]. All
conversions were automatically checked to produce the same DocBook
result when converted back, modulo minor typographical/formatting
differences on the acceptable-to-desirable spectrum.
To reproduce this commit, run:
$ NIX_PATH=nixpkgs=flake:nixpkgs/e7e69199f0372364a6106a1e735f68604f4c5a25 \
nix shell nixpkgs#coreutils \
-c find . -name '*.nix' \
-exec nix run -- github:emilazy/nix-doc-munge/98dadf1f77351c2ba5dcb709a2a171d655f15099 \
{} +
$ ./format
[my fork of `nix-doc-munge`]: https://github.com/emilazy/nix-doc-munge/tree/home-manager
53 lines
1.3 KiB
Nix
53 lines
1.3 KiB
Nix
{ config, lib, pkgs, ... }:
|
|
|
|
let
|
|
|
|
cfg = config.programs.timidity;
|
|
|
|
in {
|
|
meta.maintainers = [ lib.hm.maintainers.amesgen ];
|
|
|
|
options.programs.timidity = {
|
|
enable =
|
|
lib.mkEnableOption (lib.mdDoc "timidity, a software MIDI renderer");
|
|
|
|
package = lib.mkOption {
|
|
type = lib.types.package;
|
|
default = pkgs.timidity;
|
|
defaultText = lib.literalExpression "pkgs.timidity";
|
|
description = lib.mdDoc "The timidity package to use.";
|
|
};
|
|
|
|
finalPackage = lib.mkOption {
|
|
readOnly = true;
|
|
type = lib.types.package;
|
|
description = lib.mdDoc "Resulting package.";
|
|
};
|
|
|
|
extraConfig = lib.mkOption {
|
|
type = lib.types.lines;
|
|
default = "";
|
|
example = lib.literalExpression ''
|
|
'''
|
|
soundfont ''${pkgs.soundfont-fluid}/share/soundfonts/FluidR3_GM2-2.sf2
|
|
'''
|
|
'';
|
|
description = lib.mdDoc "Extra configuration.";
|
|
};
|
|
};
|
|
|
|
config = lib.mkIf cfg.enable {
|
|
home.packages = [ cfg.finalPackage ];
|
|
|
|
programs.timidity.finalPackage = pkgs.symlinkJoin {
|
|
name = "timidity-with-config";
|
|
paths = [ cfg.package ];
|
|
nativeBuildInputs = [ pkgs.makeWrapper ];
|
|
postBuild = ''
|
|
wrapProgram $out/bin/timidity \
|
|
--add-flags '-c ${pkgs.writeText "timidity.cfg" cfg.extraConfig}'
|
|
'';
|
|
};
|
|
};
|
|
}
|