mirror of
https://github.com/nix-community/home-manager
synced 2024-07-02 11:28:32 +02:00
36a53d9f26
This process was automated by [my fork of `nix-doc-munge`]. All
conversions were automatically checked to produce the same DocBook
result when converted back, modulo minor typographical/formatting
differences on the acceptable-to-desirable spectrum.
To reproduce this commit, run:
$ NIX_PATH=nixpkgs=flake:nixpkgs/e7e69199f0372364a6106a1e735f68604f4c5a25 \
nix shell nixpkgs#coreutils \
-c find . -name '*.nix' \
-exec nix run -- github:emilazy/nix-doc-munge/98dadf1f77351c2ba5dcb709a2a171d655f15099 \
{} +
$ ./format
[my fork of `nix-doc-munge`]: https://github.com/emilazy/nix-doc-munge/tree/home-manager
61 lines
1.5 KiB
Nix
61 lines
1.5 KiB
Nix
{ config, lib, ... }:
|
|
|
|
with lib;
|
|
|
|
let
|
|
|
|
cfg = config.programs.matplotlib;
|
|
|
|
formatLine = o: n: v:
|
|
let
|
|
formatValue = v:
|
|
if isBool v then (if v then "True" else "False") else toString v;
|
|
in if isAttrs v then
|
|
concatStringsSep "\n" (mapAttrsToList (formatLine "${o}${n}.") v)
|
|
else
|
|
(if v == "" then "" else "${o}${n}: ${formatValue v}");
|
|
|
|
in {
|
|
meta.maintainers = [ maintainers.rprospero ];
|
|
|
|
options.programs.matplotlib = {
|
|
enable =
|
|
mkEnableOption (lib.mdDoc "matplotlib, a plotting library for python");
|
|
|
|
config = mkOption {
|
|
default = { };
|
|
type = types.attrsOf types.anything;
|
|
description = lib.mdDoc ''
|
|
Add terms to the {file}`matplotlibrc` file to
|
|
control the default matplotlib behavior.
|
|
'';
|
|
example = literalExpression ''
|
|
{
|
|
backend = "Qt5Agg";
|
|
axes = {
|
|
grid = true;
|
|
facecolor = "black";
|
|
edgecolor = "FF9900";
|
|
};
|
|
grid.color = "FF9900";
|
|
}
|
|
'';
|
|
};
|
|
|
|
extraConfig = mkOption {
|
|
type = types.lines;
|
|
default = "";
|
|
description = lib.mdDoc ''
|
|
Additional commands for matplotlib that will be added to the
|
|
{file}`matplotlibrc` file.
|
|
'';
|
|
};
|
|
};
|
|
|
|
config = mkIf cfg.enable {
|
|
xdg.configFile."matplotlib/matplotlibrc".text = concatStringsSep "\n" ([ ]
|
|
++ mapAttrsToList (formatLine "") cfg.config
|
|
++ optional (cfg.extraConfig != "") cfg.extraConfig) + "\n";
|
|
};
|
|
}
|