mirror of
https://github.com/nix-community/home-manager
synced 2024-07-02 11:28:32 +02:00
36a53d9f26
This process was automated by [my fork of `nix-doc-munge`]. All
conversions were automatically checked to produce the same DocBook
result when converted back, modulo minor typographical/formatting
differences on the acceptable-to-desirable spectrum.
To reproduce this commit, run:
$ NIX_PATH=nixpkgs=flake:nixpkgs/e7e69199f0372364a6106a1e735f68604f4c5a25 \
nix shell nixpkgs#coreutils \
-c find . -name '*.nix' \
-exec nix run -- github:emilazy/nix-doc-munge/98dadf1f77351c2ba5dcb709a2a171d655f15099 \
{} +
$ ./format
[my fork of `nix-doc-munge`]: https://github.com/emilazy/nix-doc-munge/tree/home-manager
60 lines
1.4 KiB
Nix
60 lines
1.4 KiB
Nix
{ config, lib, pkgs, ... }:
|
|
|
|
with lib;
|
|
|
|
let
|
|
|
|
cfg = config.programs.librewolf;
|
|
|
|
mkOverridesFile = prefs: ''
|
|
// Generated by Home Manager.
|
|
|
|
${concatStrings (mapAttrsToList (name: value: ''
|
|
defaultPref("${name}", ${builtins.toJSON value});
|
|
'') prefs)}
|
|
'';
|
|
|
|
in {
|
|
meta.maintainers = [ maintainers.onny ];
|
|
|
|
options.programs.librewolf = {
|
|
enable = mkEnableOption
|
|
(lib.mdDoc "Librewolf browser, a privacy enhanced Firefox fork");
|
|
|
|
package = mkOption {
|
|
type = types.package;
|
|
default = pkgs.librewolf;
|
|
defaultText = literalExpression "pkgs.librewolf";
|
|
description = lib.mdDoc "The LibreWolf package to use.";
|
|
};
|
|
|
|
settings = mkOption {
|
|
type = with types; attrsOf (either bool (either int str));
|
|
default = { };
|
|
example = literalExpression ''
|
|
{
|
|
"webgl.disabled" = false;
|
|
"privacy.resistFingerprinting" = false;
|
|
}
|
|
'';
|
|
description = lib.mdDoc ''
|
|
Attribute set of LibreWolf settings and overrides. Refer to
|
|
<https://librewolf.net/docs/settings/>
|
|
for details on supported values.
|
|
'';
|
|
};
|
|
};
|
|
|
|
config = mkIf cfg.enable {
|
|
assertions = [
|
|
(lib.hm.assertions.assertPlatform "programs.librewolf" pkgs
|
|
lib.platforms.linux)
|
|
];
|
|
|
|
home.packages = [ cfg.package ];
|
|
|
|
home.file.".librewolf/librewolf.overrides.cfg".text =
|
|
mkOverridesFile cfg.settings;
|
|
};
|
|
}
|