mirror of
https://github.com/nix-community/home-manager
synced 2024-10-01 02:37:27 +02:00
36a53d9f26
This process was automated by [my fork of `nix-doc-munge`]. All
conversions were automatically checked to produce the same DocBook
result when converted back, modulo minor typographical/formatting
differences on the acceptable-to-desirable spectrum.
To reproduce this commit, run:
$ NIX_PATH=nixpkgs=flake:nixpkgs/e7e69199f0372364a6106a1e735f68604f4c5a25 \
nix shell nixpkgs#coreutils \
-c find . -name '*.nix' \
-exec nix run -- github:emilazy/nix-doc-munge/98dadf1f77351c2ba5dcb709a2a171d655f15099 \
{} +
$ ./format
[my fork of `nix-doc-munge`]: https://github.com/emilazy/nix-doc-munge/tree/home-manager
58 lines
1.3 KiB
Nix
58 lines
1.3 KiB
Nix
{ config, lib, pkgs, ... }:
|
|
|
|
with lib;
|
|
|
|
let
|
|
cfg = config.programs.aria2;
|
|
|
|
formatLine = n: v:
|
|
let
|
|
formatValue = v:
|
|
if builtins.isBool v then
|
|
(if v then "true" else "false")
|
|
else
|
|
toString v;
|
|
in "${n}=${formatValue v}";
|
|
in {
|
|
meta.maintainers = [ hm.maintainers.justinlovinger ];
|
|
|
|
options.programs.aria2 = {
|
|
enable = mkEnableOption (lib.mdDoc "aria2");
|
|
|
|
settings = mkOption {
|
|
type = with types; attrsOf (oneOf [ bool float int str ]);
|
|
default = { };
|
|
description = lib.mdDoc ''
|
|
Options to add to {file}`aria2.conf` file.
|
|
See
|
|
{manpage}`aria2c(1)`
|
|
for options.
|
|
'';
|
|
example = literalExpression ''
|
|
{
|
|
listen-port = 60000;
|
|
dht-listen-port = 60000;
|
|
seed-ratio = 1.0;
|
|
max-upload-limit = "50K";
|
|
ftp-pasv = true;
|
|
}
|
|
'';
|
|
};
|
|
|
|
extraConfig = mkOption {
|
|
type = types.lines;
|
|
default = "";
|
|
description = lib.mdDoc ''
|
|
Extra lines added to {file}`aria2.conf` file.
|
|
'';
|
|
};
|
|
};
|
|
|
|
config = mkIf cfg.enable {
|
|
home.packages = [ pkgs.aria2 ];
|
|
|
|
xdg.configFile."aria2/aria2.conf".text = concatStringsSep "\n" ([ ]
|
|
++ mapAttrsToList formatLine cfg.settings
|
|
++ optional (cfg.extraConfig != "") cfg.extraConfig);
|
|
};
|
|
}
|