mirror of
https://github.com/nix-community/home-manager
synced 2025-01-23 09:29:50 +01:00
6a9f87b3aa
As per systemd.special(7)[0] graphical-session-pre.target is strictly for units that set up things for a graphical session. Most notably, these are usually started *before* the compositor/session is actually ready. While Home Manager's current implementation of graphical-session.target allows these units to work regardless of what systemd.special(7) specifies, other setups like ones with uwsm[1] do not allow these units to start properly. [0]: https://www.freedesktop.org/software/systemd/man/latest/systemd.special.html#graphical-session-pre.target [1]: https://github.com/Vladimir-csp/uwsm Signed-off-by: Sefa Eyeoglu <contact@scrumplex.net>
84 lines
2.4 KiB
Nix
84 lines
2.4 KiB
Nix
{ config, lib, pkgs, ... }:
|
|
|
|
with lib;
|
|
|
|
let
|
|
|
|
cfg = config.services.xcape;
|
|
|
|
in {
|
|
meta.maintainers = [ maintainers.nickhu ];
|
|
|
|
options = {
|
|
services.xcape = {
|
|
enable = mkEnableOption "xcape";
|
|
|
|
timeout = mkOption {
|
|
type = types.nullOr types.int;
|
|
default = null;
|
|
example = 500;
|
|
description = ''
|
|
If you hold a key longer than this timeout, xcape will not
|
|
generate a key event. Default is 500 ms.
|
|
'';
|
|
};
|
|
|
|
mapExpression = mkOption {
|
|
type = types.attrsOf types.str;
|
|
default = { };
|
|
example = {
|
|
Shift_L = "Escape";
|
|
Control_L = "Control_L|O";
|
|
};
|
|
description = ''
|
|
The value has the grammar `Key[|OtherKey]`.
|
|
|
|
The list of key names is found in the header file
|
|
{file}`X11/keysymdef.h` (remove the
|
|
`XK_` prefix). Note that due to limitations
|
|
of X11 shifted keys must be specified as a shift key
|
|
followed by the key to be pressed rather than the actual
|
|
name of the character. For example to generate "{" the
|
|
expression `Shift_L|bracketleft` could be
|
|
used (assuming that you have a key with "{" above "[").
|
|
|
|
You can also specify keys in decimal (prefix #), octal (#0),
|
|
or hexadecimal (#0x). They will be interpreted as keycodes
|
|
unless no corresponding key name is found.
|
|
'';
|
|
};
|
|
};
|
|
};
|
|
|
|
config = mkIf cfg.enable {
|
|
assertions = [
|
|
(lib.hm.assertions.assertPlatform "services.xcape" pkgs
|
|
lib.platforms.linux)
|
|
];
|
|
|
|
systemd.user.services.xcape = {
|
|
Unit = mkMerge [
|
|
{
|
|
Description = "xcape";
|
|
After = [ "graphical-session.target" ];
|
|
PartOf = [ "graphical-session.target" ];
|
|
}
|
|
(mkIf (config.home.keyboard != null && config.home.keyboard != { }) {
|
|
After = [ "graphical-session.target" "setxkbmap.service" ];
|
|
})
|
|
];
|
|
|
|
Service = {
|
|
Type = "forking";
|
|
ExecStart = "${pkgs.xcape}/bin/xcape"
|
|
+ optionalString (cfg.timeout != null) " -t ${toString cfg.timeout}"
|
|
+ optionalString (cfg.mapExpression != { }) " -e '${
|
|
builtins.concatStringsSep ";"
|
|
(attrsets.mapAttrsToList (n: v: "${n}=${v}") cfg.mapExpression)
|
|
}'";
|
|
};
|
|
|
|
Install = { WantedBy = [ "graphical-session.target" ]; };
|
|
};
|
|
};
|
|
}
|