mirror of
https://github.com/nix-community/home-manager
synced 2025-02-02 14:25:04 +01:00
6a9f87b3aa
As per systemd.special(7)[0] graphical-session-pre.target is strictly for units that set up things for a graphical session. Most notably, these are usually started *before* the compositor/session is actually ready. While Home Manager's current implementation of graphical-session.target allows these units to work regardless of what systemd.special(7) specifies, other setups like ones with uwsm[1] do not allow these units to start properly. [0]: https://www.freedesktop.org/software/systemd/man/latest/systemd.special.html#graphical-session-pre.target [1]: https://github.com/Vladimir-csp/uwsm Signed-off-by: Sefa Eyeoglu <contact@scrumplex.net>
70 lines
1.8 KiB
Nix
70 lines
1.8 KiB
Nix
{ config, lib, pkgs, ... }:
|
|
|
|
with lib;
|
|
|
|
let
|
|
|
|
jsonFormat = pkgs.formats.json { };
|
|
cfg = config.services.plex-mpv-shim;
|
|
|
|
in {
|
|
meta.maintainers = [ maintainers.starcraft66 ];
|
|
|
|
options = {
|
|
services.plex-mpv-shim = {
|
|
enable = mkEnableOption "Plex mpv shim";
|
|
|
|
package = mkOption {
|
|
type = types.package;
|
|
default = pkgs.plex-mpv-shim;
|
|
defaultText = literalExpression "pkgs.plex-mpv-shim";
|
|
description = "The package to use for the Plex mpv shim.";
|
|
};
|
|
|
|
settings = mkOption {
|
|
type = jsonFormat.type;
|
|
default = { };
|
|
example = literalExpression ''
|
|
{
|
|
adaptive_transcode = false;
|
|
allow_http = false;
|
|
always_transcode = false;
|
|
audio_ac3passthrough = false;
|
|
audio_dtspassthrough = false;
|
|
auto_play = true;
|
|
auto_transcode = true;
|
|
}
|
|
'';
|
|
description = ''
|
|
Configuration written to
|
|
{file}`$XDG_CONFIG_HOME/plex-mpv-shim/config.json`. See
|
|
<https://github.com/iwalton3/plex-mpv-shim/blob/master/README.md>
|
|
for the configuration documentation.
|
|
'';
|
|
};
|
|
};
|
|
};
|
|
|
|
config = mkIf cfg.enable {
|
|
assertions = [
|
|
(lib.hm.assertions.assertPlatform "services.plex-mpv-shim" pkgs
|
|
lib.platforms.linux)
|
|
];
|
|
|
|
xdg.configFile."plex-mpv-shim/conf.json" = mkIf (cfg.settings != { }) {
|
|
source = jsonFormat.generate "conf.json" cfg.settings;
|
|
};
|
|
|
|
systemd.user.services.plex-mpv-shim = {
|
|
Unit = {
|
|
Description = "Plex mpv shim";
|
|
After = [ "graphical-session.target" ];
|
|
PartOf = [ "graphical-session.target" ];
|
|
};
|
|
|
|
Service = { ExecStart = "${cfg.package}/bin/plex-mpv-shim"; };
|
|
|
|
Install = { WantedBy = [ "graphical-session.target" ]; };
|
|
};
|
|
};
|
|
}
|