mirror of
https://github.com/nix-community/home-manager
synced 2025-01-23 09:29:50 +01:00
6a9f87b3aa
As per systemd.special(7)[0] graphical-session-pre.target is strictly for units that set up things for a graphical session. Most notably, these are usually started *before* the compositor/session is actually ready. While Home Manager's current implementation of graphical-session.target allows these units to work regardless of what systemd.special(7) specifies, other setups like ones with uwsm[1] do not allow these units to start properly. [0]: https://www.freedesktop.org/software/systemd/man/latest/systemd.special.html#graphical-session-pre.target [1]: https://github.com/Vladimir-csp/uwsm Signed-off-by: Sefa Eyeoglu <contact@scrumplex.net>
52 lines
1.3 KiB
Nix
52 lines
1.3 KiB
Nix
{ config, lib, pkgs, ... }:
|
|
|
|
with lib;
|
|
|
|
let
|
|
|
|
cfg = config.services.nextcloud-client;
|
|
|
|
in {
|
|
options = {
|
|
services.nextcloud-client = {
|
|
enable = mkEnableOption "Nextcloud Client";
|
|
|
|
package = mkOption {
|
|
type = types.package;
|
|
default = pkgs.nextcloud-client;
|
|
defaultText = literalExpression "pkgs.nextcloud-client";
|
|
description = "The package to use for the nextcloud client binary.";
|
|
};
|
|
|
|
startInBackground = mkOption {
|
|
type = types.bool;
|
|
default = false;
|
|
description =
|
|
"Whether to start the Nextcloud client in the background.";
|
|
};
|
|
};
|
|
};
|
|
|
|
config = mkIf cfg.enable {
|
|
assertions = [
|
|
(lib.hm.assertions.assertPlatform "services.nextcloud-client" pkgs
|
|
lib.platforms.linux)
|
|
];
|
|
|
|
systemd.user.services.nextcloud-client = {
|
|
Unit = {
|
|
Description = "Nextcloud Client";
|
|
After = [ "graphical-session.target" ];
|
|
PartOf = [ "graphical-session.target" ];
|
|
};
|
|
|
|
Service = {
|
|
Environment = [ "PATH=${config.home.profileDirectory}/bin" ];
|
|
ExecStart = "${cfg.package}/bin/nextcloud"
|
|
+ (optionalString cfg.startInBackground " --background");
|
|
};
|
|
|
|
Install = { WantedBy = [ "graphical-session.target" ]; };
|
|
};
|
|
};
|
|
}
|