mirror of
https://github.com/nix-community/home-manager
synced 2025-01-23 09:29:50 +01:00
6a9f87b3aa
As per systemd.special(7)[0] graphical-session-pre.target is strictly for units that set up things for a graphical session. Most notably, these are usually started *before* the compositor/session is actually ready. While Home Manager's current implementation of graphical-session.target allows these units to work regardless of what systemd.special(7) specifies, other setups like ones with uwsm[1] do not allow these units to start properly. [0]: https://www.freedesktop.org/software/systemd/man/latest/systemd.special.html#graphical-session-pre.target [1]: https://github.com/Vladimir-csp/uwsm Signed-off-by: Sefa Eyeoglu <contact@scrumplex.net>
79 lines
2 KiB
Nix
79 lines
2 KiB
Nix
{ config, lib, pkgs, ... }:
|
|
|
|
with lib;
|
|
let cfg = config.services.barrier;
|
|
in {
|
|
|
|
meta.maintainers = with maintainers; [ kritnich ];
|
|
|
|
imports = [
|
|
(mkRemovedOptionModule [ "services" "barrier" "client" "tray" ] ''
|
|
The tray option is non-functional and has been removed.
|
|
'')
|
|
];
|
|
|
|
options.services.barrier = {
|
|
|
|
client = {
|
|
|
|
enable = mkEnableOption "Barrier Client daemon";
|
|
|
|
name = mkOption {
|
|
type = types.nullOr types.str;
|
|
default = null;
|
|
description = ''
|
|
Screen name of client. Defaults to hostname.
|
|
'';
|
|
};
|
|
|
|
server = mkOption {
|
|
type = types.str;
|
|
description = ''
|
|
Server to connect to formatted as
|
|
`<host>[:<port>]`.
|
|
Port defaults to `24800`.
|
|
'';
|
|
};
|
|
|
|
enableCrypto = mkEnableOption "crypto (SSL) plugin" // {
|
|
default = true;
|
|
};
|
|
|
|
enableDragDrop = mkEnableOption "file drag & drop";
|
|
|
|
extraFlags = mkOption {
|
|
type = types.listOf types.str;
|
|
default = [ "-f" ];
|
|
defaultText = literalExpression ''[ "-f" ]'';
|
|
description = ''
|
|
Additional flags to pass to {command}`barrierc`.
|
|
See {command}`barrierc --help`.
|
|
'';
|
|
};
|
|
|
|
};
|
|
};
|
|
|
|
config = mkIf cfg.client.enable {
|
|
assertions = [
|
|
(lib.hm.assertions.assertPlatform "services.barrier" pkgs
|
|
lib.platforms.linux)
|
|
];
|
|
|
|
systemd.user.services.barrierc = {
|
|
Unit = {
|
|
Description = "Barrier Client daemon";
|
|
After = [ "graphical-session.target" ];
|
|
PartOf = [ "graphical-session.target" ];
|
|
};
|
|
Install.WantedBy = [ "graphical-session.target" ];
|
|
Service.ExecStart = with cfg.client;
|
|
toString ([ "${pkgs.barrier}/bin/barrierc" ]
|
|
++ optional (name != null) "--name ${name}"
|
|
++ optional (!enableCrypto) "--disable-crypto"
|
|
++ optional enableDragDrop "--enable-drag-drop" ++ extraFlags
|
|
++ [ server ]);
|
|
};
|
|
};
|
|
|
|
}
|