mirror of
https://github.com/nix-community/home-manager
synced 2024-06-02 21:13:33 +02:00
64ab7d6e8d
* Add flake.lock and clean up flake.nix Add a lockfile to work around https://github.com/NixOS/nix/issues/6541 (and because it's a good idea anyway). Also use flake-utils, and restrict ourselves to the five platforms supported by nixpkgs. Otherwise, the IFD for nmd fails on weird platforms. This fixes `nix flake check`. Remove the redundant `apps` output, see https://github.com/nix-community/home-manager/pull/2442#issuecomment-1133670487 * nixos,nix-darwin: factor out into a common module * nixos,nix-darwin: make `home-managers.users` shallowly visible Make sure the option is included in the NixOS/nix-darwin manual (but the HM submodule options aren't). Also add a static description to the HM submodule type so that we don't need to evaluate the submodules just to build the option manual. This makes nixos-search able to index the home-manager flake. Also clean up some TODOs. * flake: add nmd and nmt This avoids having to use `pkgs.fetchFromGitLab` in an IFD, which causes issues when indexing packages with nixos-search because `pkgs` is instantiated with every platform.
57 lines
1.8 KiB
Nix
57 lines
1.8 KiB
Nix
{ runCommand, lib, bash, callPackage, coreutils, findutils, gettext, gnused
|
|
, less
|
|
# used for pkgs.path for nixos-option
|
|
, pkgs
|
|
|
|
# Extra path to Home Manager. If set then this path will be tried
|
|
# before `$HOME/.config/nixpkgs/home-manager` and
|
|
# `$HOME/.nixpkgs/home-manager`.
|
|
, path ? null }:
|
|
|
|
let
|
|
|
|
pathStr = if path == null then "" else path;
|
|
|
|
nixos-option = pkgs.nixos-option or (callPackage
|
|
(pkgs.path + "/nixos/modules/installer/tools/nixos-option") { });
|
|
|
|
in runCommand "home-manager" {
|
|
preferLocalBuild = true;
|
|
nativeBuildInputs = [ gettext ];
|
|
meta = with lib; {
|
|
mainProgram = "home-manager";
|
|
description = "A user environment configurator";
|
|
maintainers = [ maintainers.rycee ];
|
|
platforms = platforms.unix;
|
|
license = licenses.mit;
|
|
};
|
|
} ''
|
|
install -v -D -m755 ${./home-manager} $out/bin/home-manager
|
|
|
|
substituteInPlace $out/bin/home-manager \
|
|
--subst-var-by bash "${bash}" \
|
|
--subst-var-by DEP_PATH "${
|
|
lib.makeBinPath [ coreutils findutils gettext gnused less nixos-option ]
|
|
}" \
|
|
--subst-var-by HOME_MANAGER_LIB '${../lib/bash/home-manager.sh}' \
|
|
--subst-var-by HOME_MANAGER_PATH '${pathStr}' \
|
|
--subst-var-by OUT "$out"
|
|
|
|
install -D -m755 ${./completion.bash} \
|
|
$out/share/bash-completion/completions/home-manager
|
|
install -D -m755 ${./completion.zsh} \
|
|
$out/share/zsh/site-functions/_home-manager
|
|
install -D -m755 ${./completion.fish} \
|
|
$out/share/fish/vendor_completions.d/home-manager.fish
|
|
|
|
install -D -m755 ${../lib/bash/home-manager.sh} \
|
|
"$out/share/bash/home-manager.sh"
|
|
|
|
for path in ${./po}/*.po; do
|
|
lang="''${path##*/}"
|
|
lang="''${lang%%.*}"
|
|
mkdir -p "$out/share/locale/$lang/LC_MESSAGES"
|
|
msgfmt -o "$out/share/locale/$lang/LC_MESSAGES/home-manager.mo" "$path"
|
|
done
|
|
''
|