mirror of
https://github.com/nix-community/home-manager
synced 2024-11-30 15:09:46 +01:00
36a53d9f26
This process was automated by [my fork of `nix-doc-munge`]. All
conversions were automatically checked to produce the same DocBook
result when converted back, modulo minor typographical/formatting
differences on the acceptable-to-desirable spectrum.
To reproduce this commit, run:
$ NIX_PATH=nixpkgs=flake:nixpkgs/e7e69199f0372364a6106a1e735f68604f4c5a25 \
nix shell nixpkgs#coreutils \
-c find . -name '*.nix' \
-exec nix run -- github:emilazy/nix-doc-munge/98dadf1f77351c2ba5dcb709a2a171d655f15099 \
{} +
$ ./format
[my fork of `nix-doc-munge`]: https://github.com/emilazy/nix-doc-munge/tree/home-manager
86 lines
2.3 KiB
Nix
86 lines
2.3 KiB
Nix
{ config, lib, pkgs, ... }:
|
|
|
|
with lib;
|
|
|
|
let
|
|
|
|
cfg = config.services.vdirsyncer;
|
|
|
|
vdirsyncerOptions = [ ]
|
|
++ optional (cfg.verbosity != null) "--verbosity ${cfg.verbosity}"
|
|
++ optional (cfg.configFile != null) "--config ${cfg.configFile}";
|
|
|
|
in {
|
|
meta.maintainers = [ maintainers.pjones ];
|
|
|
|
options.services.vdirsyncer = {
|
|
enable = mkEnableOption (lib.mdDoc "vdirsyncer");
|
|
|
|
package = mkOption {
|
|
type = types.package;
|
|
default = pkgs.vdirsyncer;
|
|
defaultText = "pkgs.vdirsyncer";
|
|
example = literalExpression "pkgs.vdirsyncer";
|
|
description = lib.mdDoc "The package to use for the vdirsyncer binary.";
|
|
};
|
|
|
|
frequency = mkOption {
|
|
type = types.str;
|
|
default = "*:0/5";
|
|
description = lib.mdDoc ''
|
|
How often to run vdirsyncer. This value is passed to the systemd
|
|
timer configuration as the onCalendar option. See
|
|
{manpage}`systemd.time(7)`
|
|
for more information about the format.
|
|
'';
|
|
};
|
|
|
|
verbosity = mkOption {
|
|
type = types.nullOr
|
|
(types.enum [ "CRITICAL" "ERROR" "WARNING" "INFO" "DEBUG" ]);
|
|
default = null;
|
|
description = lib.mdDoc ''
|
|
Whether vdirsyncer should produce verbose output.
|
|
'';
|
|
};
|
|
|
|
configFile = mkOption {
|
|
type = types.nullOr types.path;
|
|
default = null;
|
|
description = lib.mdDoc ''
|
|
Optional configuration file to link to use instead of
|
|
the default file ({file}`$XDG_CONFIG_HOME/vdirsyncer/config`).
|
|
'';
|
|
};
|
|
};
|
|
|
|
config = mkIf cfg.enable {
|
|
systemd.user.services.vdirsyncer = {
|
|
Unit = {
|
|
Description = "vdirsyncer calendar&contacts synchronization";
|
|
PartOf = [ "network-online.target" ];
|
|
};
|
|
|
|
Service = {
|
|
Type = "oneshot";
|
|
# TODO `vdirsyncer discover`
|
|
ExecStart = let optStr = concatStringsSep " " vdirsyncerOptions;
|
|
in [
|
|
"${cfg.package}/bin/vdirsyncer ${optStr} metasync"
|
|
"${cfg.package}/bin/vdirsyncer ${optStr} sync"
|
|
];
|
|
};
|
|
};
|
|
|
|
systemd.user.timers.vdirsyncer = {
|
|
Unit = { Description = "vdirsyncer calendar&contacts synchronization"; };
|
|
|
|
Timer = {
|
|
OnCalendar = cfg.frequency;
|
|
Unit = "vdirsyncer.service";
|
|
};
|
|
|
|
Install = { WantedBy = [ "timers.target" ]; };
|
|
};
|
|
};
|
|
}
|