mirror of
https://github.com/nix-community/home-manager
synced 2024-11-27 13:39:46 +01:00
36a53d9f26
This process was automated by [my fork of `nix-doc-munge`]. All
conversions were automatically checked to produce the same DocBook
result when converted back, modulo minor typographical/formatting
differences on the acceptable-to-desirable spectrum.
To reproduce this commit, run:
$ NIX_PATH=nixpkgs=flake:nixpkgs/e7e69199f0372364a6106a1e735f68604f4c5a25 \
nix shell nixpkgs#coreutils \
-c find . -name '*.nix' \
-exec nix run -- github:emilazy/nix-doc-munge/98dadf1f77351c2ba5dcb709a2a171d655f15099 \
{} +
$ ./format
[my fork of `nix-doc-munge`]: https://github.com/emilazy/nix-doc-munge/tree/home-manager
73 lines
1.7 KiB
Nix
73 lines
1.7 KiB
Nix
{ config, lib, pkgs, ... }:
|
|
|
|
with lib;
|
|
|
|
let
|
|
|
|
cfg = config.services.pbgopy;
|
|
package = pkgs.pbgopy;
|
|
|
|
commandLine = concatStringsSep " " ([
|
|
"${package}/bin/pbgopy serve"
|
|
"--port ${toString cfg.port}"
|
|
"--ttl ${cfg.cache.ttl}"
|
|
] ++ optional (cfg.httpAuth != null)
|
|
"--basic-auth ${escapeShellArg cfg.httpAuth}");
|
|
|
|
in {
|
|
meta.maintainers = [ maintainers.ivar ];
|
|
|
|
options.services.pbgopy = {
|
|
enable = mkEnableOption (lib.mdDoc "pbgopy");
|
|
|
|
port = mkOption {
|
|
type = types.port;
|
|
default = 9090;
|
|
example = 8080;
|
|
description = lib.mdDoc ''
|
|
The port to host the pbgopy server on.
|
|
'';
|
|
};
|
|
|
|
cache.ttl = mkOption {
|
|
type = types.str;
|
|
default = "24h";
|
|
example = "10m";
|
|
description = lib.mdDoc ''
|
|
The TTL for the cache. Use `"0s"` to disable it.
|
|
'';
|
|
};
|
|
|
|
httpAuth = mkOption {
|
|
type = types.nullOr types.str;
|
|
default = null;
|
|
example = "user:pass";
|
|
description = lib.mdDoc ''
|
|
Basic HTTP authentication's username and password. Both the username and
|
|
password are escaped.
|
|
'';
|
|
};
|
|
};
|
|
|
|
config = mkIf cfg.enable {
|
|
assertions = [
|
|
(lib.hm.assertions.assertPlatform "services.pbgopy" pkgs
|
|
lib.platforms.linux)
|
|
];
|
|
|
|
home.packages = [ package ];
|
|
|
|
systemd.user.services.pbgopy = {
|
|
Unit = {
|
|
Description = "pbgopy server for sharing the clipboard between devices";
|
|
After = [ "graphical-session-pre.target" ];
|
|
PartOf = [ "graphical-session.target" ];
|
|
};
|
|
Service = {
|
|
ExecStart = commandLine;
|
|
Restart = "on-abort";
|
|
};
|
|
Install = { WantedBy = [ "graphical-session.target" ]; };
|
|
};
|
|
};
|
|
}
|