mirror of
https://github.com/nix-community/home-manager
synced 2024-11-18 00:59:44 +01:00
9dad146639
Add new options Darwin options: - `targets.darwin.defaults` This adds options for configuring macOS through the `defaults(1)` system. This option can be used to manipulate a vast majority of user settings for macOS and its applications. This is implemented using freeform modules and includes additional descriptions and type information for some useful options. - `targets.darwin.keybindings` This adds options for configuring the default keybindings for macOS text fields. - `targets.darwin.search` This adds options for configuring the default search engine for macOS.
42 lines
1.3 KiB
Nix
42 lines
1.3 KiB
Nix
{ config, lib, pkgs, ... }:
|
|
|
|
with lib;
|
|
|
|
let
|
|
cfg = config.targets.darwin;
|
|
homeDir = config.home.homeDirectory;
|
|
confFile = pkgs.writeText "DefaultKeybinding.dict"
|
|
(lib.generators.toPlist { } cfg.keybindings);
|
|
in {
|
|
options.targets.darwin.keybindings = mkOption {
|
|
type = with types; attrsOf anything;
|
|
default = { };
|
|
example = {
|
|
"^u" = "deleteToBeginningOfLine:";
|
|
"^w" = "deleteWordBackward:";
|
|
};
|
|
description = ''
|
|
This will configure the default keybindings for text fields in macOS
|
|
applications. See
|
|
<link xlink:href="https://developer.apple.com/library/archive/documentation/Cocoa/Conceptual/EventOverview/TextDefaultsBindings/TextDefaultsBindings.html">Apple's documentation</link>
|
|
for more details.
|
|
|
|
<warning>
|
|
<para>
|
|
Existing keybinding configuration will be wiped when using this
|
|
option.
|
|
</para>
|
|
</warning>
|
|
'';
|
|
};
|
|
|
|
config = mkIf (cfg.keybindings != { }) {
|
|
# NOTE: just copy the files because symlinks won't be recognized by macOS
|
|
home.activation.setCocoaKeybindings =
|
|
hm.dag.entryAfter [ "writeBoundary" ] ''
|
|
$VERBOSE_ECHO "Configuring keybindings for the Cocoa Text System"
|
|
$DRY_RUN_CMD install -Dm644 $VERBOSE_ARG \
|
|
"${confFile}" "${homeDir}/Library/KeyBindings/DefaultKeyBinding.dict"
|
|
'';
|
|
};
|
|
}
|