mirror of
https://github.com/nix-community/home-manager
synced 2024-07-02 19:38:32 +02:00
c7592b747b
Currently, dot directories and XDG base directories are used inconsistently in the Home Manager option declarations. This creates ambiguity for the user as to where the location of the file should be albeit this is rarely encountered in practice as it is sufficient to read upstream documentation. The rationale is to make declarations consistent and make a clear distinction between hardcoded and modular specifications. References to ~/.config in relevant nixpkgs modules were untouched as the location is hardcoded upstream[1]. Furthermore, modules of programs which do not follow XDG specifications were also untouched. Generalization of tilde(~) expansions to $HOME were also considered, however there isn't sufficient rationale despite the use of $HOME being more universal. The expansion is standardized in POSIX[2] and is essentially portable across all shells, thus there is no pragmatic value to introducing the change. [1] https://github.com/nixos/nixpkgs/blob/master/pkgs/top-level/impure.nix [2] https://pubs.opengroup.org/onlinepubs/009695399/utilities/xcu_chap02.html#tag_02_06_01
113 lines
2.9 KiB
Nix
113 lines
2.9 KiB
Nix
{ config, lib, pkgs, ... }:
|
|
|
|
with lib;
|
|
|
|
let
|
|
|
|
cfg = config.programs.direnv;
|
|
|
|
tomlFormat = pkgs.formats.toml { };
|
|
|
|
in {
|
|
imports = [
|
|
(mkRenamedOptionModule [
|
|
"programs"
|
|
"direnv"
|
|
"enableNixDirenvIntegration"
|
|
] [ "programs" "direnv" "nix-direnv" "enable" ])
|
|
(mkRemovedOptionModule [ "programs" "direnv" "nix-direnv" "enableFlakes" ]
|
|
"Flake support is now always enabled.")
|
|
];
|
|
|
|
meta.maintainers = [ maintainers.rycee ];
|
|
|
|
options.programs.direnv = {
|
|
enable = mkEnableOption "direnv, the environment switcher";
|
|
|
|
config = mkOption {
|
|
type = tomlFormat.type;
|
|
default = { };
|
|
description = ''
|
|
Configuration written to
|
|
<filename>$XDG_CONFIG_HOME/direnv/config.toml</filename>.
|
|
</para><para>
|
|
See
|
|
<citerefentry>
|
|
<refentrytitle>direnv.toml</refentrytitle>
|
|
<manvolnum>1</manvolnum>
|
|
</citerefentry>.
|
|
for the full list of options.
|
|
'';
|
|
};
|
|
|
|
stdlib = mkOption {
|
|
type = types.lines;
|
|
default = "";
|
|
description = ''
|
|
Custom stdlib written to
|
|
<filename>$XDG_CONFIG_HOME/direnv/direnvrc</filename>.
|
|
'';
|
|
};
|
|
|
|
enableBashIntegration = mkOption {
|
|
default = true;
|
|
type = types.bool;
|
|
description = ''
|
|
Whether to enable Bash integration.
|
|
'';
|
|
};
|
|
|
|
enableZshIntegration = mkOption {
|
|
default = true;
|
|
type = types.bool;
|
|
description = ''
|
|
Whether to enable Zsh integration.
|
|
'';
|
|
};
|
|
|
|
enableFishIntegration = mkOption {
|
|
default = true;
|
|
type = types.bool;
|
|
readOnly = true;
|
|
description = ''
|
|
Whether to enable Fish integration. Note, enabling the direnv module
|
|
will always active its functionality for Fish since the direnv package
|
|
automatically gets loaded in Fish.
|
|
'';
|
|
};
|
|
|
|
nix-direnv = {
|
|
enable = mkEnableOption ''
|
|
<link
|
|
xlink:href="https://github.com/nix-community/nix-direnv">nix-direnv</link>,
|
|
a fast, persistent use_nix implementation for direnv'';
|
|
};
|
|
|
|
};
|
|
|
|
config = mkIf cfg.enable {
|
|
home.packages = [ pkgs.direnv ];
|
|
|
|
xdg.configFile."direnv/config.toml" = mkIf (cfg.config != { }) {
|
|
source = tomlFormat.generate "direnv-config" cfg.config;
|
|
};
|
|
|
|
xdg.configFile."direnv/direnvrc" = let
|
|
text = concatStringsSep "\n" (optional (cfg.stdlib != "") cfg.stdlib
|
|
++ optional cfg.nix-direnv.enable
|
|
"source ${pkgs.nix-direnv}/share/nix-direnv/direnvrc");
|
|
in mkIf (text != "") { inherit text; };
|
|
|
|
programs.bash.initExtra = mkIf cfg.enableBashIntegration (
|
|
# Using mkAfter to make it more likely to appear after other
|
|
# manipulations of the prompt.
|
|
mkAfter ''
|
|
eval "$(${pkgs.direnv}/bin/direnv hook bash)"
|
|
'');
|
|
|
|
programs.zsh.initExtra = mkIf cfg.enableZshIntegration ''
|
|
eval "$(${pkgs.direnv}/bin/direnv hook zsh)"
|
|
'';
|
|
};
|
|
}
|