mirror of
https://github.com/nix-community/home-manager
synced 2024-12-30 13:49:47 +01:00
c7592b747b
Currently, dot directories and XDG base directories are used inconsistently in the Home Manager option declarations. This creates ambiguity for the user as to where the location of the file should be albeit this is rarely encountered in practice as it is sufficient to read upstream documentation. The rationale is to make declarations consistent and make a clear distinction between hardcoded and modular specifications. References to ~/.config in relevant nixpkgs modules were untouched as the location is hardcoded upstream[1]. Furthermore, modules of programs which do not follow XDG specifications were also untouched. Generalization of tilde(~) expansions to $HOME were also considered, however there isn't sufficient rationale despite the use of $HOME being more universal. The expansion is standardized in POSIX[2] and is essentially portable across all shells, thus there is no pragmatic value to introducing the change. [1] https://github.com/nixos/nixpkgs/blob/master/pkgs/top-level/impure.nix [2] https://pubs.opengroup.org/onlinepubs/009695399/utilities/xcu_chap02.html#tag_02_06_01
128 lines
3.7 KiB
Nix
128 lines
3.7 KiB
Nix
{ config, lib, pkgs, ... }:
|
|
|
|
with lib;
|
|
|
|
let
|
|
cfg = config.programs.sm64ex;
|
|
|
|
# This is required for tests, we cannot overwrite the dummy package.
|
|
package = if cfg.region == null && cfg.baserom == null
|
|
&& cfg.extraCompileFlags == null then
|
|
cfg.package
|
|
|
|
else
|
|
cfg.package.override (attrs:
|
|
{ } // optionalAttrs (cfg.region != null) { region = cfg.region; }
|
|
// optionalAttrs (cfg.baserom != null) { baseRom = cfg.baserom; }
|
|
// optionalAttrs (cfg.extraCompileFlags != null) {
|
|
compileFlags = cfg.extraCompileFlags;
|
|
});
|
|
|
|
mkConfig = key: value:
|
|
let
|
|
generatedValue = if isBool value then
|
|
(if value then "true" else "false")
|
|
else if isList value then
|
|
concatStringsSep " " value
|
|
else
|
|
toString value;
|
|
in "${key} ${generatedValue}";
|
|
|
|
in {
|
|
meta.maintainers = [ maintainers.ivar ];
|
|
|
|
options.programs.sm64ex = {
|
|
enable = mkEnableOption "sm64ex";
|
|
|
|
package = mkOption {
|
|
type = types.package;
|
|
default = pkgs.sm64ex;
|
|
description = "The sm64ex package to use.";
|
|
};
|
|
|
|
region = mkOption {
|
|
type = types.nullOr (types.enum [ "us" "eu" "jp" ]);
|
|
default = null;
|
|
defaultText =
|
|
literalExpression "us"; # This is set both in nixpkgs and upstream
|
|
description = ''
|
|
Your baserom's region. Note that only "us", "eu", and "jp" are supported.
|
|
'';
|
|
example = literalExpression "jp";
|
|
};
|
|
|
|
baserom = mkOption {
|
|
type = types.nullOr types.path;
|
|
default = null;
|
|
description =
|
|
"The path to the Super Mario 64 baserom to extract assets from.";
|
|
example = literalExpression "/home/foo/baserom.us.z64";
|
|
};
|
|
|
|
extraCompileFlags = mkOption {
|
|
type = with types; nullOr (listOf str);
|
|
default = null;
|
|
description = ''
|
|
Extra flags to pass to the compiler. See
|
|
<link xlink:href="https://github.com/sm64pc/sm64ex/wiki/Build-options"/>
|
|
for more information.
|
|
'';
|
|
example = literalExpression ''
|
|
[
|
|
"BETTERCAMERA=1"
|
|
"NODRAWINGDISTANCE=1"
|
|
];
|
|
'';
|
|
};
|
|
|
|
settings = mkOption {
|
|
type = with types;
|
|
nullOr (attrsOf (either str (either int (either bool (listOf str)))));
|
|
default = null;
|
|
description =
|
|
"Settings for sm64ex's <filename>$XDG_DATA_HOME/sm64pc/sm64config.txt</filename> file.";
|
|
example = literalExpression ''
|
|
{
|
|
fullscreen = false;
|
|
window_x = 0;
|
|
window_y = 0;
|
|
window_w = 1920;
|
|
window_h = 1080;
|
|
vsync = 1;
|
|
texture_filtering = 1;
|
|
master_volume = 127;
|
|
music_volume = 127;
|
|
sfx_volume = 127;
|
|
env_volume = 127;
|
|
key_a = [ "0026" "1000" "1103" ];
|
|
key_b = [ "0033" "1002" "1101" ];
|
|
key_start = [ "0039" "1006" "ffff" ];
|
|
key_l = [ "0034" "1007" "1104" ];
|
|
key_r = [ "0036" "100a" "1105" ];
|
|
key_z = [ "0025" "1009" "1102" ];
|
|
key_cup = [ "100b" "ffff" "ffff" ];
|
|
key_cdown = [ "100c" "ffff" "ffff" ];
|
|
key_cleft = [ "100d" "ffff" "ffff" ];
|
|
key_cright = [ "100e" "ffff" "ffff" ];
|
|
key_stickup = [ "0011" "ffff" "ffff" ];
|
|
key_stickdown = [ "001f" "ffff" "ffff" ];
|
|
key_stickleft = [ "001e" "ffff" "ffff" ];
|
|
key_stickright = [ "0020" "ffff" "ffff" ];
|
|
stick_deadzone = 16;
|
|
rumble_strength = 10;
|
|
skip_intro = 1;
|
|
};
|
|
'';
|
|
};
|
|
};
|
|
|
|
config = let
|
|
configFile = optionals (cfg.settings != null)
|
|
(concatStringsSep "\n" ((mapAttrsToList mkConfig cfg.settings)));
|
|
in mkIf cfg.enable {
|
|
home.packages = [ package ];
|
|
|
|
xdg.dataFile."sm64pc/sm64config.txt" =
|
|
mkIf (cfg.settings != null) { text = configFile; };
|
|
};
|
|
}
|