mirror of
https://github.com/nix-community/home-manager
synced 2024-06-02 13:03:33 +02:00
c049a09d1a
* pulseeffects: change default example pulseeffects-pw is now an alias to easyeffects, and the `pulseeffects` binary that this module references is no longer in that package. * easyeffects: add module The easyeffects service is the PipeWire equivalent of the pulseeffects service.
64 lines
1.8 KiB
Nix
64 lines
1.8 KiB
Nix
{ config, lib, pkgs, ... }:
|
|
|
|
with lib;
|
|
|
|
let
|
|
|
|
cfg = config.services.easyeffects;
|
|
|
|
presetOpts = optionalString (cfg.preset != "") "--load-preset ${cfg.preset}";
|
|
|
|
in {
|
|
meta.maintainers = [ maintainers.fufexan ];
|
|
|
|
options.services.easyeffects = {
|
|
enable = mkEnableOption ''
|
|
Easyeffects daemon.
|
|
Note, it is necessary to add
|
|
<programlisting language="nix">
|
|
services.dbus.packages = with pkgs; [ gnome.dconf ];
|
|
</programlisting>
|
|
to your system configuration for the daemon to work correctly
|
|
'';
|
|
|
|
preset = mkOption {
|
|
type = types.str;
|
|
default = "";
|
|
description = ''
|
|
Which preset to use when starting easyeffects.
|
|
Will likely need to launch easyeffects to initially create preset.
|
|
'';
|
|
};
|
|
};
|
|
|
|
config = mkIf cfg.enable {
|
|
assertions = [
|
|
(hm.assertions.assertPlatform "services.easyeffects" pkgs platforms.linux)
|
|
];
|
|
|
|
# running easyeffects will just attach itself to gapplication service
|
|
# at-spi2-core is to minimize journalctl noise of:
|
|
# "AT-SPI: Error retrieving accessibility bus address: org.freedesktop.DBus.Error.ServiceUnknown: The name org.a11y.Bus was not provided by any .service files"
|
|
home.packages = with pkgs; [ easyeffects at-spi2-core ];
|
|
|
|
systemd.user.services.easyeffects = {
|
|
Unit = {
|
|
Description = "Easyeffects daemon";
|
|
Requires = [ "dbus.service" ];
|
|
After = [ "graphical-session-pre.target" ];
|
|
PartOf = [ "graphical-session.target" "pipewire.service" ];
|
|
};
|
|
|
|
Install.WantedBy = [ "graphical-session.target" ];
|
|
|
|
Service = {
|
|
ExecStart =
|
|
"${pkgs.easyeffects}/bin/easyeffects --gapplication-service ${presetOpts}";
|
|
ExecStop = "${pkgs.easyeffects}/bin/easyeffects --quit";
|
|
Restart = "on-failure";
|
|
RestartSec = 5;
|
|
};
|
|
};
|
|
};
|
|
}
|